1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
220
  
221
  
222
  
223
  
224
  
225
  
226
  
227
  
228
  
229
  
230
  
231
  
232
  
233
  
234
  
235
  
236
  
237
  
238
  
239
  
240
  
241
  
242
  
243
  
244
  
245
  
246
  
247
  
248
  
249
  
250
  
251
  
252
  
253
  
254
  
255
  
256
  
257
  
258
  
259
  
260
  
261
  
262
  
263
  
264
  
265
  
266
  
267
  
268
  
269
  
270
  
271
  
272
  
273
  
274
  
275
  
276
  
277
  
278
  
279
  
280
  
281
  
282
  
283
  
284
  
285
  
286
  
287
  
288
  
289
  
290
  
291
  
292
  
293
  
294
  
295
  
296
  
297
  
298
  
299
  
300
  
301
  
302
  
303
  
304
  
305
  
306
  
307
  
308
  
309
  
310
  
311
  
312
  
313
  
314
  
315
  
316
  
317
  
318
  
319
  
320
  
321
  
322
  
323
  
324
  
325
  
326
  
327
  
328
  
329
  
330
  
331
  
332
  
333
  
334
  
335
  
336
  
337
  
338
  
339
  
340
  
341
  
342
  
343
  
344
  
345
  
346
  
347
  
348
  
349
  
350
  
351
  
352
  
353
  
354
  
355
  
356
  
357
  
358
  
359
  
360
  
361
  
362
  
363
  
364
  
365
  
366
  
367
  
368
  
369
  
370
  
371
  
372
  
373
  
374
  
375
  
376
  
377
  
378
  
379
  
380
  
381
  
382
  
383
  
384
  
385
  
386
  
387
  
388
  
389
  
390
  
391
  
392
  
393
  
394
  
395
  
396
  
397
  
398
  
399
  
400
  
401
  
402
  
403
  
404
  
405
  
406
  
407
  
408
  
409
  
410
  
411
  
412
  
413
  
414
  
415
  
416
  
417
  
418
  
419
  
420
  
421
  
422
  
423
  
424
  
425
  
426
  
427
  
428
  
429
  
430
  
431
  
432
  
433
  
434
  
435
  
436
  
437
  
438
  
439
  
440
  
441
  
442
  
443
  
444
  
445
  
446
  
447
  
448
  
449
  
450
  
451
  
452
  
453
  
454
  
455
  
456
  
457
  
458
  
459
  
460
  
461
  
462
  
463
  
464
  
465
  
466
  
467
  
468
  
469
  
470
  
471
  
472
  
473
  
474
  
475
  
476
  
477
  
478
  
479
  
480
  
481
  
482
  
483
  
484
  
485
  
486
  
487
  
488
  
489
  
490
  
491
  
492
  
493
  
494
  
495
  
496
  
497
  
498
  
499
  
500
  
501
  
502
  
503
  
504
  
505
  
506
  
507
  
508
  
509
  
510
  
511
  
512
  
513
  
514
  
515
  
516
  
517
  
518
  
519
  
520
  
521
  
522
  
523
  
524
  
525
  
526
  
527
  
528
  
529
  
530
  
531
  
532
  
533
  
534
  
535
  
536
  
537
  
538
  
539
  
540
  
541
  
542
  
543
  
544
  
545
  
546
  
547
  
548
  
549
  
550
  
551
  
552
  
553
  
554
  
555
  
556
  
557
  
558
  
559
  
560
  
561
  
562
  
563
  
564
  
565
  
566
  
567
  
568
  
569
  
570
  
571
  
572
  
573
  
574
  
575
  
576
  
577
  
578
  
579
  
580
  
581
  
582
  
583
  
584
  
585
  
586
  
587
  
588
  
589
  
590
  
591
  
592
  
593
  
594
  
595
  
596
  
597
  
598
  
599
  
600
  
601
  
602
  
603
  
604
  
605
  
606
  
607
  
608
  
609
  
610
  
611
  
612
  
613
  
614
  
615
  
616
  
617
  
618
  
619
  
620
  
621
  
622
  
623
  
624
  
625
  
626
  
627
  
628
  
629
  
630
  
631
  
632
  
633
  
634
  
635
  
636
  
637
  
638
  
639
  
640
  
641
  
642
  
643
  
644
  
645
  
646
  
647
  
648
  
649
  
650
  
651
  
652
  
653
  
654
  
655
  
656
  
657
  
658
  
659
  
660
  
661
  
662
  
663
  
664
  
665
  
666
  
667
  
668
  
669
  
670
  
671
  
672
  
673
  
674
  
675
  
676
  
677
  
678
  
679
  
680
  
681
  
682
  
683
  
684
  
685
  
686
  
687
  
688
  
689
  
690
  
691
  
692
  
693
  
694
  
695
  
696
  
697
  
698
  
699
  
700
  
701
  
702
  
703
  
704
  
705
  
706
  
707
  
708
  
709
  
710
  
711
  
712
  
713
  
714
  
715
  
716
  
717
  
718
  
719
  
720
  
721
  
722
  
723
  
724
  
725
  
726
  
727
  
728
  
729
  
730
  
731
  
732
  
733
  
734
  
735
  
736
  
737
  
738
  
739
  
740
  
741
  
742
  
743
  
744
  
745
  
746
  
747
  
748
  
749
  
750
  
751
  
752
  
753
  
754
  
755
  
756
  
757
  
758
  
759
  
760
  
761
  
762
  
763
  
764
  
765
  
766
  
767
  
768
  
769
  
770
  
771
  
772
  
773
  
774
  
775
  
776
  
777
  
778
  
779
  
780
  
781
  
782
  
783
  
784
  
785
  
786
  
787
  
788
  
789
  
790
  
791
  
792
  
793
  
794
  
795
  
796
  
797
  
798
  
799
  
800
  
801
  
802
  
803
  
804
  
805
  
806
  
807
  
808
  
809
  
810
  
811
  
812
  
813
  
814
  
815
  
816
  
817
  
818
  
819
  
820
  
821
  
822
  
823
  
824
  
825
  
826
  
827
  
828
  
829
  
830
  
831
  
832
  
833
  
834
  
835
  
836
  
837
  
838
  
839
  
840
  
841
  
842
  
843
  
844
  
845
  
846
  
847
  
848
  
849
  
850
  
851
  
852
  
853
  
854
  
855
  
856
  
857
  
858
  
859
  
860
  
861
  
862
  
863
  
864
  
865
  
866
  
867
  
868
  
869
  
870
  
871
  
872
  
873
  
874
  
875
  
876
  
877
  
878
  
879
  
880
  
881
  
882
  
883
  
884
  
885
  
886
  
887
  
888
  
889
  
890
  
891
  
892
  
893
  
894
  
895
  
896
  
897
  
898
  
899
  
900
  
901
  
902
  
903
  
904
  
905
  
906
  
907
  
908
  
909
  
910
  
911
  
912
  
913
  
914
  
915
  
916
  
917
  
918
  
919
  
920
  
921
  
922
  
923
  
924
  
925
  
926
  
927
  
928
  
929
  
930
  
931
  
932
  
933
  
934
  
935
  
936
  
937
  
938
  
939
  
940
  
941
  
942
  
943
  
944
  
945
  
946
  
947
  
948
  
949
  
950
  
951
  
952
  
953
  
954
  
955
  
956
  
957
  
958
  
959
  
960
  
961
  
962
  
963
  
964
  
965
  
966
  
967
  
968
  
969
  
970
  
971
  
972
  
973
  
974
  
975
  
976
  
977
  
978
  
979
  
980
  
981
  
982
  
983
  
984
  
985
  
986
  
987
  
988
  
989
  
990
  
991
  
992
  
993
  
994
  
995
  
996
  
997
  
998
  
999
  
1000
  
1001
  
1002
  
1003
  
1004
  
1005
  
1006
  
1007
  
1008
  
1009
  
1010
  
1011
  
1012
  
1013
  
1014
  
1015
  
1016
  
1017
  
1018
  
1019
  
1020
  
1021
  
1022
  
1023
  
1024
  
1025
  
1026
  
1027
  
1028
  
1029
  
1030
  
1031
  
1032
  
1033
  
1034
  
1035
  
1036
  
1037
  
1038
  
1039
  
1040
  
1041
  
1042
  
1043
  
1044
  
1045
  
1046
  
1047
  
1048
  
1049
  
1050
  
1051
  
1052
  
1053
  
1054
  
1055
  
1056
  
1057
  
1058
  
1059
  
1060
  
1061
  
1062
  
1063
  
1064
  
1065
  
1066
  
1067
  
1068
  
1069
  
1070
  
1071
  
1072
  
1073
  
1074
  
1075
  
1076
  
1077
  
1078
  
1079
  
1080
  
1081
  
1082
  
1083
  
1084
  
1085
  
1086
  
1087
  
1088
  
1089
  
1090
  
1091
  
1092
  
1093
  
1094
  
1095
  
1096
  
1097
  
1098
  
1099
  
1100
  
1101
  
1102
  
1103
  
1104
  
1105
  
1106
  
1107
  
1108
  
1109
  
1110
  
1111
  
1112
  
1113
  
1114
  
1115
  
1116
  
1117
  
1118
  
1119
  
1120
  
1121
  
1122
  
1123
  
1124
  
1125
  
1126
  
1127
  
1128
  
1129
  
1130
  
1131
  
1132
  
1133
  
1134
  
1135
  
1136
  
1137
  
1138
  
1139
  
1140
  
1141
  
1142
  
1143
  
1144
  
1145
  
1146
  
1147
  
1148
  
1149
  
1150
  
1151
  
1152
  
1153
  
1154
  
1155
  
1156
  
1157
  
1158
  
1159
  
1160
  
1161
  
1162
  
1163
  
1164
  
1165
  
1166
  
1167
  
1168
  
1169
  
1170
  
1171
  
1172
  
1173
  
1174
  
1175
  
1176
  
1177
  
1178
  
1179
  
1180
  
1181
  
1182
  
1183
  
1184
  
1185
  
1186
  
1187
  
1188
  
1189
  
1190
  
1191
  
1192
  
1193
  
1194
  
1195
  
1196
  
1197
  
1198
  
1199
  
1200
  
1201
  
1202
  
1203
  
1204
  
1205
  
1206
  
1207
  
1208
  
1209
  
1210
  
1211
  
1212
  
1213
  
1214
  
1215
  
1216
  
1217
  
1218
  
1219
  
1220
  
1221
  
1222
  
1223
  
1224
  
1225
  
1226
  
1227
  
1228
  
1229
  
1230
  
1231
  
1232
  
1233
  
1234
  
1235
  
1236
  
1237
  
1238
  
1239
  
1240
  
1241
  
1242
  
1243
  
1244
  
1245
  
1246
  
1247
  
1248
  
1249
  
1250
  
1251
  
1252
  
1253
  
1254
  
1255
  
1256
  
1257
  
1258
  
1259
  
1260
  
1261
  
1262
  
1263
  
1264
  
1265
  
1266
  
1267
  
1268
  
1269
  
1270
  
1271
  
1272
  
1273
  
1274
  
1275
  
1276
  
1277
  
1278
  
1279
  
1280
  
1281
  
1282
  
1283
  
1284
  
1285
  
1286
  
1287
  
1288
  
1289
  
1290
  
1291
  
1292
  
1293
  
1294
  
1295
  
1296
  
1297
  
1298
  
1299
  
1300
  
1301
  
1302
  
1303
  
1304
  
1305
  
1306
  
1307
  
1308
  
1309
  
1310
  
1311
  
1312
  
1313
  
1314
  
1315
  
1316
  
1317
  
1318
  
1319
  
1320
  
1321
  
1322
  
1323
  
1324
  
1325
  
1326
  
1327
  
1328
  
1329
  
1330
  
1331
  
1332
  
1333
  
1334
  
1335
  
1336
  
1337
  
1338
  
// This file is part of Roxen WebServer. 
// Copyright © 1996 - 2001, Roxen IS. 
// $Id: module.pike,v 1.174 2004/05/04 15:02:20 mast Exp $ 
 
#include <module_constants.h> 
#include <module.h> 
#include <request_trace.h> 
 
constant __pragma_save_parent__ = 1; 
 
inherit "basic_defvar"; 
mapping(string:array(int)) error_log=([]); 
 
constant is_module = 1; 
// constant module_type = MODULE_ZERO; 
// constant module_name    = "Unnamed module"; 
// constant module_doc     = "Undocumented"; 
constant module_unique  = 1; 
 
 
private Configuration _my_configuration; 
private string _module_local_identifier; 
private string _module_identifier = 
  lambda() { 
    mixed init_info = roxen->bootstrap_info->get(); 
    if (arrayp (init_info)) { 
      [_my_configuration, _module_local_identifier] = init_info; 
      return _my_configuration->name + "/" + _module_local_identifier; 
    } 
  }(); 
static mapping _api_functions = ([]); 
 
string|array(string) module_creator; 
string module_url; 
RXML.TagSet module_tag_set; 
 
/* These functions exists in here because otherwise the messages in 
 * the event log does not always end up in the correct 
 * module/configuration.  And the reason for that is that if the 
 * messages are logged from subclasses in the module, the DWIM in 
 * roxenlib.pike cannot see that they are logged from a module. This 
 * solution is not really all that beautiful, but it works. :-) 
 */ 
void report_fatal( mixed ... args )  { predef::report_fatal( @args );  } 
void report_error( mixed ... args )  { predef::report_error( @args );  } 
void report_notice( mixed ... args ) { predef::report_notice( @args ); } 
void report_debug( mixed ... args )  { predef::report_debug( @args );  } 
 
 
string module_identifier() 
//! Returns a string that uniquely identifies this module instance 
//! within the server. The identifier is the same as 
//! @[Roxen.get_module] and @[Roxen.get_modname] handles. 
{ 
#if 1 
  return _module_identifier; 
#else 
  if (!_module_identifier) { 
    string|mapping name = this_object()->register_module()[1]; 
    if (mappingp (name)) name = name->standard; 
    string cname = sprintf ("%O", my_configuration()); 
    if (sscanf (cname, "Configuration(%s", cname) == 1 && 
        sizeof (cname) && cname[-1] == ')') 
      cname = cname[..sizeof (cname) - 2]; 
    _module_identifier = sprintf ("%s,%s", 
                                  name||this_object()->module_name, cname); 
  } 
  return _module_identifier; 
#endif 
} 
 
string module_local_id() 
//! Returns a string that uniquely identifies this module instance 
//! within the configuration. The returned string is the same as the 
//! part after the first '/' in the one returned from 
//! @[module_identifier]. 
{ 
  return _module_local_identifier; 
} 
 
RoxenModule this_module() 
{ 
  return this_object(); // To be used from subclasses. 
} 
 
string _sprintf() 
{ 
  return sprintf ("RoxenModule(%s)", _module_identifier || "?"); 
} 
 
array register_module() 
{ 
  return ({ 
    this_object()->module_type, 
    this_object()->module_name, 
    this_object()->module_doc, 
    0, 
    module_unique, 
    this_object()->module_locked, 
  }); 
} 
 
string fix_cvs(string from) 
{ 
  from = replace(from, ({ "$", "Id: "," Exp $" }), ({"","",""})); 
  sscanf(from, "%*s,v %s", from); 
  return replace(from,"/","-"); 
} 
 
int module_dependencies(Configuration configuration, 
                        array (string) modules, 
                        int|void now) 
//! If your module depends on other modules present in the server, 
//! calling <pi>module_dependencies()</pi>, supplying an array of 
//! module identifiers. A module identifier is either the filename 
//! minus extension, or a string on the form that Roxen.get_modname 
//! returns. In the latter case, the <config name> and <copy> parts 
//! are ignored. 
{ 
  modules = map (modules, 
                 lambda (string modname) { 
                   sscanf ((modname / "/")[-1], "%[^#]", modname); 
                   return modname; 
                 }); 
  Configuration conf = configuration || my_configuration(); 
  if (!conf) 
    report_warning ("Configuration not resolved; module(s) %s that %s " 
                    "depend on weren't added.", String.implode_nicely (modules), 
                    module_identifier()); 
  else 
    conf->add_modules( modules, now ); 
  return 1; 
} 
 
string file_name_and_stuff() 
{ 
  return ("<b>Loaded from:</b> "+(roxen->filename(this_object()))+"<br>"+ 
          (this_object()->cvs_version? 
           "<b>CVS Version:</b> "+ 
           fix_cvs(this_object()->cvs_version)+"\n":"")); 
} 
 
 
Configuration my_configuration() 
//! Returns the Configuration object of the virtual server the module 
//! belongs to. 
{ 
  return _my_configuration; 
} 
 
nomask void set_configuration(Configuration c) 
{ 
  if(_my_configuration && _my_configuration != c) 
    error("set_configuration() called twice.\n"); 
  _my_configuration = c; 
} 
 
void set_module_creator(string|array(string) c) 
//! Set the name and optionally email address of the author of the 
//! module. Names on the format "author name <author_email>" will 
//! end up as links on the module's information page in the admin 
//! interface. In the case of multiple authors, an array of such 
//! strings can be passed. 
{ 
  module_creator = c; 
} 
 
void set_module_url(string to) 
//! A common way of referring to a location where you maintain 
//! information about your module or similar. The URL will turn up 
//! on the module's information page in the admin interface, 
//! referred to as the module's home page. 
{ 
  module_url = to; 
} 
 
void free_some_sockets_please(){} 
 
void start(void|int num, void|Configuration conf) {} 
 
string status() {} 
 
string info(Configuration conf) 
{ 
 return (this_object()->register_module()[2]); 
} 
 
string sname( ) 
{ 
  return my_configuration()->otomod[ this_object() ]; 
} 
 
ModuleInfo my_moduleinfo( ) 
//! Returns the associated @[ModuleInfo] object 
{ 
  string f = sname(); 
  if( f ) return roxen.find_module( (f/"#")[0] ); 
} 
 
void save_me() 
{ 
  my_configuration()->save_one( this_object() ); 
  my_configuration()->module_changed( my_moduleinfo(), this_object() ); 
} 
 
void save()      { save_me(); } 
string comment() { return ""; } 
 
string query_internal_location() 
//! Returns the internal mountpoint, where <ref>find_internal()</ref> 
//! is mounted. 
{ 
  if(!_my_configuration) 
    error("Please do not call this function from create()!\n"); 
  return _my_configuration->query_internal_location(this_object()); 
} 
 
string query_absolute_internal_location(RequestID id) 
//! Returns the internal mountpoint as an absolute path. 
{ 
  return (id->misc->site_prefix_path || "") + query_internal_location(); 
} 
 
string query_location() 
//! Returns the mountpoint as an absolute path. The default 
//! implementation uses the "location" configuration variable in the 
//! module. 
{ 
  string s; 
  catch{s = query("location");}; 
  return s; 
} 
 
array(string) location_urls() 
//! Returns an array of all locations where the module is mounted. 
{ 
  string loc = query_location(); 
  if (!loc) return ({}); 
  if(!_my_configuration) 
    error("Please do not call this function from create()!\n"); 
  array(string) urls = copy_value(_my_configuration->query("URLs")); 
  string hostname; 
  if (string world_url = _my_configuration->query ("MyWorldLocation")) 
    sscanf (world_url, "%*s://%s%*[:/]", hostname); 
  if (!hostname) hostname = gethostname(); 
  for (int i = 0; i < sizeof (urls); i++) 
  { 
    urls[i] = (urls[i]/"#")[0]; 
    if (sizeof (urls[i]/"*") == 2) 
      urls[i] = replace(urls[i], "*", hostname); 
  } 
  return map (urls, `+, loc[1..]); 
} 
 
/* By default, provide nothing. */ 
string query_provides() { return 0; } 
 
 
function(RequestID:int|mapping) query_seclevels() 
{ 
  if(catch(query("_seclevels")) || (query("_seclevels") == 0)) 
    return 0; 
  return roxen.compile_security_pattern(query("_seclevels"),this_object()); 
} 
 
Stat stat_file(string f, RequestID id){} 
array(string) find_dir(string f, RequestID id){} 
mapping(string:Stat) find_dir_stat(string f, RequestID id) 
{ 
  SIMPLE_TRACE_ENTER(this, "find_dir_stat(): %O", f); 
 
  array(string) files = find_dir(f, id); 
  mapping(string:Stat) res = ([]); 
 
  foreach(files || ({}), string fname) { 
    SIMPLE_TRACE_ENTER(this, "stat()'ing %O", f + "/" + fname); 
    Stat st = stat_file(replace(f + "/" + fname, "//", "/"), id); 
    if (st) { 
      res[fname] = st; 
      TRACE_LEAVE("OK"); 
    } else { 
      TRACE_LEAVE("No stat info"); 
    } 
  } 
 
  TRACE_LEAVE(""); 
  return(res); 
} 
 
class DefaultPropertySet 
{ 
  inherit PropertySet; 
 
  static Stat stat; 
 
  static void create (string path, RequestID id, Stat stat) 
  { 
    ::create (path, id); 
    this_program::stat = stat; 
  } 
 
  Stat get_stat() {return stat;} 
 
  static mapping(string:string) response_headers; 
 
  mapping(string:string) get_response_headers() 
  { 
    if (!response_headers) { 
      // Old kludge inherited from configuration.try_get_file. 
      if (!id->misc->common) 
        id->misc->common = ([]); 
 
      RequestID sub_id = id->clone_me(); 
      sub_id->misc->common = id->misc->common; 
 
      sub_id->not_query = query_location() + path; 
      sub_id->raw_url = replace (id->raw_url, id->not_query, sub_id->not_query); 
      sub_id->method = "HEAD"; 
 
      mapping(string:mixed)|int(-1..0)|object res = find_file (path, sub_id); 
      if (res == -1) res = ([]); 
      else if (objectp (res)) { 
        string ext; 
        if(stringp(sub_id->extension)) { 
          sub_id->not_query += sub_id->extension; 
          ext = lower_case(Roxen.extension(sub_id->not_query, sub_id)); 
        } 
        array(string) tmp=sub_id->conf->type_from_filename(sub_id->not_query, 1, ext); 
        if(tmp) 
          res = ([ "file":res, "type":tmp[0], "encoding":tmp[1] ]); 
        else 
          res = (["file": res]); 
      } 
      response_headers = sub_id->make_response_headers (res); 
      destruct (sub_id); 
    } 
 
    return response_headers; 
  } 
} 
 
//! Return the set of properties for @[path]. 
//! 
//! @returns 
//!   Returns @tt{0@} (zero) if @[path] does not exist. 
//! 
//!   Returns an error mapping if there's some other error accessing 
//!   the properties. 
//! 
//!   Otherwise returns a @[PropertySet] object. 
PropertySet|mapping(string:mixed) query_properties(string path, RequestID id) 
{ 
  SIMPLE_TRACE_ENTER (this, "Querying properties on %O", path); 
  Stat st = stat_file(path, id); 
 
  if (!st) { 
    SIMPLE_TRACE_LEAVE ("No such file or dir"); 
    return 0; 
  } 
 
  PropertySet res = DefaultPropertySet(path, id, st); 
  SIMPLE_TRACE_LEAVE (""); 
  return res; 
} 
 
//! Returns the value of the specified property, or an error code 
//! mapping. 
//! 
//! @note 
//!   Returning a string is shorthand for returning an array 
//!   with a single text node. 
string|array(Parser.XML.Tree.Node)|mapping(string:mixed) 
  query_property(string path, string prop_name, RequestID id) 
{ 
  mapping(string:mixed)|PropertySet properties = query_properties(path, id); 
  if (!properties) { 
    return Roxen.http_status(Protocols.HTTP.HTTP_NOT_FOUND, 
                             "No such file or directory."); 
  } 
  if (mappingp (properties)) 
    return properties; 
  return properties->query_property(prop_name) || 
    Roxen.http_status(Protocols.HTTP.HTTP_NOT_FOUND, "No such property."); 
} 
 
//! RFC 2518 PROPFIND implementation with recursion according to 
//! @[depth]. See @[find_properties] for details. 
void recurse_find_properties(string path, string mode, 
                             int depth, MultiStatus result, 
                             RequestID id, 
                             multiset(string)|void filt) 
{ 
  SIMPLE_TRACE_ENTER (this, "%s for %O, depth %d", 
                      mode == "DAV:propname" ? "Listing property names" : 
                      mode == "DAV:allprop" ? "Retrieving all properties" : 
                      mode == "DAV:prop" ? "Retrieving specific properties" : 
                      "Finding properties with mode " + mode, 
                      path, depth); 
  mapping(string:mixed)|PropertySet properties = query_properties(path, id); 
 
  if (!properties) { 
    SIMPLE_TRACE_LEAVE ("No such file or dir"); 
    return; 
  } 
 
  { 
    mapping(string:mixed) ret = mappingp (properties) ? 
      properties : properties->find_properties(mode, result, filt); 
 
    if (ret) { 
      result->add_response(path, XMLStatusNode(ret->error, ret->rettext)); 
      if (ret->rettext) { 
        Parser.XML.Tree.ElementNode descr = 
          Parser.XML.Tree.ElementNode ("DAV:responsedescription", ([])); 
        descr->add_child (Parser.XML.Tree.TextNode (ret->rettext)); 
        result->add_response (path, descr); 
      } 
      SIMPLE_TRACE_LEAVE ("Got status %d: %O", ret->error, ret->rettext); 
      return; 
    } 
  } 
 
  if (properties->get_stat()->isdir) { 
    if (depth <= 0) { 
      SIMPLE_TRACE_LEAVE ("Not recursing due to depth limit"); 
      return; 
    } 
    depth--; 
    foreach(find_dir(path, id) || ({}), string filename) { 
      recurse_find_properties(combine_path(path, filename), mode, depth, 
                              result, id, filt); 
    } 
  } 
 
  SIMPLE_TRACE_LEAVE (""); 
  return; 
} 
 
mapping(string:mixed) patch_properties(string path, 
                                       array(PatchPropertyCommand) instructions, 
                                       MultiStatus result, RequestID id) 
{ 
  SIMPLE_TRACE_ENTER (this, "Patching properties for %O", path); 
  mapping(string:mixed)|PropertySet properties = query_properties(path, id); 
 
  if (!properties) { 
    SIMPLE_TRACE_LEAVE ("No such file or dir"); 
    return 0; 
  } 
  if (mappingp (properties)) { 
    SIMPLE_TRACE_LEAVE ("Got error %d from query_properties: %O", 
                        properties->error, properties->rettext); 
    return properties; 
  } 
 
  mapping(string:mixed) errcode = properties->start(); 
 
  if (errcode) { 
    SIMPLE_TRACE_LEAVE ("Got error %d from PropertySet.start: %O", 
                        errcode->error, errcode->rettext); 
    return errcode; 
  } 
 
  array(mapping(string:mixed)) results; 
 
  mixed err = catch { 
      results = instructions->execute(properties); 
    }; 
  if (err) { 
    properties->unroll(); 
    throw (err); 
  } else { 
    int any_failed; 
    foreach(results, mapping(string:mixed) answer) { 
      if (any_failed = (answer && (answer->error >= 300))) { 
        break; 
      } 
    } 
    if (any_failed) { 
      // Unroll and fail any succeeded items. 
      int i; 
      mapping(string:mixed) answer = 
        Roxen.http_status (Protocols.HTTP.DAV_FAILED_DEP, "Failed dependency."); 
      for(i = 0; i < sizeof(results); i++) { 
        if (!results[i] || results[i]->error < 300) { 
          result->add_property(path, instructions[i]->property_name, 
                               answer); 
        } else { 
          result->add_property(path, instructions[i]->property_name, 
                               results[i]); 
        } 
      } 
      properties->unroll(); 
    } else { 
      int i; 
      for(i = 0; i < sizeof(results); i++) { 
        result->add_property(path, instructions[i]->property_name, 
                             results[i]); 
      } 
      properties->commit(); 
    } 
  } 
 
  SIMPLE_TRACE_LEAVE (""); 
  return 0; 
} 
 
//! Convenience variant of @[patch_properties()] that sets a single 
//! property. 
//! 
//! @returns 
//!   Returns a mapping on any error, zero otherwise. 
mapping(string:mixed) set_property (string path, string prop_name, 
                                    string|array(Parser.XML.Tree.Node) value, 
                                    RequestID id) 
{ 
  mapping(string:mixed)|PropertySet properties = query_properties(path, id); 
  if (!properties) return Roxen.http_status(Protocols.HTTP.HTTP_NOT_FOUND, 
                                            "File not found."); 
  if (mappingp (properties)) return properties; 
 
  mapping(string:mixed) result = properties->start(); 
  if (result) return result; 
 
  result = properties->set_property(prop_name, value); 
  if (result && result->error >= 300) { 
    properties->unroll(); 
    return result; 
  } 
 
  properties->commit(); 
  return 0; 
} 
 
//! Convenience variant of @[patch_properties()] that removes a single 
//! property. 
//! 
//! @returns 
//!   Returns a mapping on any error, zero otherwise. 
mapping(string:mixed) remove_property (string path, string prop_name, 
                                       RequestID id) 
{ 
  mapping(string:mixed)|PropertySet properties = query_properties(path, id); 
  if (!properties) return Roxen.http_status(Protocols.HTTP.HTTP_NOT_FOUND, 
                                            "File not found."); 
  if (mappingp (properties)) return properties; 
 
  mapping(string:mixed) result = properties->start(); 
  if (result) return result; 
 
  result = properties->remove_property(prop_name); 
  if (result && result->error >= 300) { 
    properties->unroll(); 
    return result; 
  } 
 
  properties->commit(); 
  return 0; 
} 
 
string resource_id (string path, RequestID id) 
//! Return a string that within the filesystem uniquely identifies the 
//! resource on @[path] in the given request. This is commonly @[path] 
//! itself but can be extended with e.g. language, user or some form 
//! variable if the path is mapped to different files according to 
//! those fields. 
//! 
//! The important criteria here is that every unique returned string 
//! corresponds to a resource that can be changed independently of 
//! every other. Thus e.g. dynamic pages that evaluate to different 
//! results depending on variables or cookies etc should _not_ be 
//! mapped to more than one string by this function. It also means 
//! that if files are stored in a filesystem which is case insensitive 
//! then this function should normalize case differences. 
//! 
//! This function is used e.g by the default lock implementation to 
//! convert paths to resources that can be locked independently of 
//! each other. There's also a notion of recursive locks there, which 
//! means that a recursive lock on a certain resource identifier also 
//! locks every resource whose identifier it is a prefix of. Therefore 
//! it's typically necessary to ensure that every identifier ends with 
//! "/" so that a recursive lock on e.g. "doc/foo" doesn't lock 
//! "doc/foobar". 
//! 
//! @param path 
//! The requested path below the filesystem location. @[path] has been 
//! normalized with @[VFS.normalize_path]. 
{ 
  return has_suffix (path, "/") ? path : path + "/"; 
} 
 
mixed authenticated_user_id (RequestID id) 
//! Return a value that uniquely identifies the user that the given 
//! request is authenticated as. 
//! 
//! This function is e.g. used by the default lock implementation to 
//! tell different users holding locks apart. 
//! 
//! @note 
//! The returned value is typically a string or integer, but if it 
//! isn't then it must be able to compare for equality with 
//! @[lfun::`==] and @[lfun::__hash]. 
{ 
  // Leave this to the standard auth system by default. 
  User uid = my_configuration()->authenticate (id); 
  return uid && uid->name(); 
} 
 
// Mapping from resource id to a mapping from user id to the lock 
// that apply to the resource. 
// 
// Only used internally by the default lock implementation. 
static mapping(string:mapping(mixed:DAVLock)) file_locks = ([]); 
 
// Mapping from resource id to a mapping from user id to the lock 
// that apply recursively to the resource and all other resources 
// it's a prefix of. 
// 
// Only used internally by the default lock implementation. 
static mapping(string:mapping(mixed:DAVLock)) prefix_locks = ([]); 
 
#define LOOP_OVER_BOTH(PATH, LOCKS, CODE)                             \ 
  do {                                                                  \ 
    foreach (file_locks; PATH; LOCKS) {CODE;}                           \ 
    foreach (prefix_locks; PATH; LOCKS) {CODE;}                         \ 
  } while (0) 
 
//! Find some or all locks that apply to @[path]. 
//! 
//! @param path 
//!   Path below the filesystem location. It's normalized with 
//!   @[VFS.normalize_path] and always ends with a @expr{"/"@}. 
//! 
//! @param recursive 
//!   If @expr{1@} also return locks anywhere below @[path]. 
//! 
//! @param exclude_shared 
//!   If @expr{1@} do not return shared locks that are held by users 
//!   other than the one the request is authenticated as. (This is 
//!   appropriate to get the list of locks that would conflict if the 
//!   current user were to make a shared lock.) 
//! 
//! @returns 
//!   Returns a multiset containing all applicable locks in 
//!   this location module, or @expr{0@} (zero) if there are none. 
//! 
//! @note 
//! @[DAVLock] objects may be created if the filesystem has some 
//! persistent storage of them. The default implementation does not 
//! store locks persistently. 
//! 
//! @note 
//! The default implementation only handles the @expr{"DAV:write"@} 
//! lock type. 
multiset(DAVLock) find_locks(string path, 
                             int(0..1) recursive, 
                             int(0..1) exclude_shared, 
                             RequestID id) 
{ 
  // Common case. 
  if (!sizeof(file_locks) && !sizeof(prefix_locks)) return 0; 
 
  TRACE_ENTER(sprintf("find_locks(%O, %O, %O, X)", 
                      path, recursive, exclude_shared), this); 
 
  path = resource_id (path, id); 
 
  multiset(DAVLock) locks = (<>); 
  function(mapping(mixed:DAVLock):void) add_locks; 
 
  if (exclude_shared) { 
    mixed auth_user = authenticated_user_id (id); 
    add_locks = lambda (mapping(mixed:DAVLock) sub_locks) { 
                  foreach (sub_locks; string user; DAVLock lock) 
                    if (user == auth_user || 
                        lock->lockscope == "DAV:exclusive") 
                      locks[lock] = 1; 
                }; 
  } 
  else 
    add_locks = lambda (mapping(mixed:DAVLock) sub_locks) { 
                  locks |= mkmultiset (values (sub_locks)); 
                }; 
 
  if (file_locks[path]) { 
    add_locks (file_locks[path]); 
  } 
 
  foreach(prefix_locks; 
          string prefix; mapping(mixed:DAVLock) sub_locks) { 
    if (has_prefix(path, prefix)) { 
      add_locks (sub_locks); 
      break; 
    } 
  } 
 
  if (recursive) { 
    LOOP_OVER_BOTH (string prefix, mapping(mixed:DAVLock) sub_locks, { 
        if (has_prefix(prefix, path)) { 
          add_locks (sub_locks); 
        } 
      }); 
  } 
 
  add_locks = 0; 
 
  TRACE_LEAVE(sprintf("Done, found %d locks.", sizeof(locks))); 
 
  return sizeof(locks) && locks; 
} 
 
//! Check if there are one or more locks that apply to @[path] for the 
//! user the request is authenticated as. 
//! 
//! @param path 
//!   Path below the filesystem location. It's normalized with 
//!   @[VFS.normalize_path] and always ends with a @expr{"/"@}. 
//! 
//! @param recursive 
//!   If @expr{1@} also check recursively under @[path] for locks. 
//! 
//! @returns 
//!   @mixed 
//!     @type DAVLock 
//!       Returns the lock owned by the authenticated user that apply 
//!       to @[path]. (It doesn't matter if the @expr{recursive@} flag 
//!       in the lock doesn't match the @[recursive] argument.) 
//!     @type int(0..3) 
//!       @int 
//!         @value 0 
//!           Returns @expr{0@} if no locks apply. 
//!         @value 1 
//!           Returns @expr{1@} if there only are one or more shared 
//!           locks held by other users. 
//!         @value 2 
//!           Returns @expr{2@} if @[recursive] is set, the 
//!           authenticated user has locks under @[path] (but not on 
//!           @[path] itself), and there are no exclusive locks held 
//!           by other users. 
//!         @value 3 
//!           Returns @expr{3@} if there are one or more exclusive 
//!           locks held by other users. 
//!       @endint 
//!   @endmixed 
//! 
//! @note 
//! @[DAVLock] objects may be created if the filesystem has some 
//! persistent storage of them. The default implementation does not 
//! store locks persistently. 
//! 
//! @note 
//! The default implementation only handles the @expr{"DAV:write"@} 
//! lock type. 
DAVLock|int(0..3) check_locks(string path, 
                              int(0..1) recursive, 
                              RequestID id) 
{ 
  // Common case. 
  if (!sizeof(file_locks) && !sizeof(prefix_locks)) return 0; 
 
  TRACE_ENTER(sprintf("check_locks(%O, %d, X)", path, recursive), this); 
 
  path = resource_id (path, id); 
 
  mixed auth_user = authenticated_user_id (id); 
 
  if (DAVLock lock = 
      file_locks[path] && file_locks[path][auth_user] || 
      prefix_locks[path] && prefix_locks[path][auth_user]) { 
    TRACE_LEAVE(sprintf("Found lock %O.", lock->locktoken)); 
    return lock; 
  } 
  int(0..1) shared; 
 
  if (mapping(mixed:DAVLock) locks = file_locks[path]) { 
    foreach(locks;; DAVLock lock) { 
      if (lock->lockscope == "DAV:exclusive") { 
        TRACE_LEAVE(sprintf("Found other user's exclusive lock %O.", 
                            lock->locktoken)); 
        return 3; 
      } 
      shared = 1; 
      break; 
    } 
  } 
 
  foreach(prefix_locks; 
          string prefix; mapping(mixed:DAVLock) locks) { 
    if (has_prefix(path, prefix)) { 
      if (DAVLock lock = locks[auth_user]) return lock; 
      if (!shared) 
        // If we've found a shared lock then we won't find an 
        // exclusive one anywhere else. 
        foreach(locks;; DAVLock lock) { 
          if (lock->lockscope == "DAV:exclusive") { 
            TRACE_LEAVE(sprintf("Found other user's exclusive lock %O.", 
                                lock->locktoken)); 
            return 3; 
          } 
          shared = 1; 
          break; 
        } 
    } 
  } 
 
  if (!recursive) { 
    TRACE_LEAVE(sprintf("Returning %O.", shared)); 
    return shared; 
  } 
 
  int(0..1) locked_by_auth_user; 
 
  // We want to know if there are any locks with @[path] as prefix 
  // that apply to us. 
  LOOP_OVER_BOTH (string prefix, mapping(mixed:DAVLock) locks, { 
      if (has_prefix(prefix, path)) { 
        if (locks[auth_user]) 
          locked_by_auth_user = 1; 
        else 
          foreach(locks;; DAVLock lock) { 
            if (lock->lockscope == "DAV:exclusive") { 
              TRACE_LEAVE(sprintf("Found other user's exclusive lock %O.", 
                                  lock->locktoken)); 
              return 3; 
            } 
            shared = 1; 
            break; 
          } 
      } 
    }); 
 
  TRACE_LEAVE(sprintf("Returning %O.", locked_by_auth_user ? 2 : shared)); 
  return locked_by_auth_user ? 2 : shared; 
} 
 
//! Lock the resource at @[path] with the given @[lock]. It's already 
//! checked that no other lock that applies, i.e. a call 
//! @code{check_locks(path,lock->recursive,id)@} would return 
//! @expr{0@} or @expr{1@}. 
//! 
//! The implementation must at least support the @expr{"DAV:write"@} 
//! lock type (RFC 2518, section 7). Briefly: An exclusive lock on a 
//! file prohibits other users from changing its content. An exclusive 
//! lock on a file or directory prohibits other users from setting or 
//! deleting any of its properties. An exclusive lock on a directory 
//! prohibits other users from adding or removing files or directories 
//! in it. A shared lock prohibits other users from obtaining an 
//! exclusive lock. A resource that doesn't exist can be locked, 
//! provided the directory it would be in exists. 
//! 
//! @param path 
//!   Path below the filesystem location that the lock applies to. 
//!   It's normalized with @[VFS.normalize_path] and always ends with 
//!   a @expr{"/"@}. 
//! 
//! @param lock 
//!   The lock to register. 
//! 
//! @returns 
//!   Returns @expr{0@} if the lock is successfully installed or a 
//!   status mapping if an error occurred. 
//! 
//! @note 
//! The default implementation supports only @expr{"DAV:write"@}. It 
//! uses @[resource_id] to map paths to unique resources and 
//! @[authenticated_user_id] to tell users apart. 
mapping(string:mixed) lock_file(string path, 
                                DAVLock lock, 
                                RequestID id) 
{ 
  ASSERT_IF_DEBUG (lock->locktype == "DAV:write"); 
  TRACE_ENTER(sprintf("lock_file(%O, lock(%O), X).", path, lock->locktoken), 
              this); 
  path = resource_id (path, id); 
  mixed auth_user = authenticated_user_id (id); 
  if (lock->recursive) { 
    if (prefix_locks[path]) { 
      prefix_locks[path][auth_user] = lock; 
    } else { 
      prefix_locks[path] = ([ auth_user:lock ]); 
    } 
  } else { 
    if (file_locks[path]) { 
      file_locks[path][auth_user] = lock; 
    } else { 
      file_locks[path] = ([ auth_user:lock ]); 
    } 
  } 
  TRACE_LEAVE("Ok."); 
  return 0; 
} 
 
//! Remove @[lock] that currently is locking the resource at @[path]. 
//! 
//! @param path 
//!   Path below the filesystem location that the lock applies to. 
//!   It's normalized with @[VFS.normalize_path] and always ends with 
//!   a @expr{"/"@}. 
//! 
//! @param lock 
//!   The lock to unregister. (It must not be changed or destructed.) 
//! 
//! @returns 
//!   Returns a status mapping on any error, zero otherwise. 
mapping(string:mixed) unlock_file (string path, 
                                   DAVLock lock, 
                                   RequestID id) 
{ 
  TRACE_ENTER(sprintf("unlock_file(%O, lock(%O), X).", path, lock->locktoken), 
              this); 
  mixed auth_user = authenticated_user_id (id); 
  path = resource_id (path, id); 
  DAVLock removed_lock; 
  if (lock->recursive) { 
    removed_lock = m_delete (prefix_locks[path], auth_user); 
    if (!sizeof (prefix_locks[path])) m_delete (prefix_locks, path); 
  } 
  else { 
    removed_lock = m_delete (file_locks[path], auth_user); 
    if (!sizeof (file_locks[path])) m_delete (file_locks, path); 
  } 
  ASSERT_IF_DEBUG (!removed_lock || lock /*%O*/ == removed_lock /*%O*/, 
                   lock, removed_lock); 
  TRACE_LEAVE("Ok."); 
  return 0; 
} 
 
 
mapping(string:mixed)|int(-1..0)|Stdio.File find_file(string path, 
                                                      RequestID id); 
 
//! Delete the file specified by @[path]. 
//! 
//! @note 
//!   Should return a 204 status on success. 
//! 
//! @note 
//!   The default implementation falls back to @[find_file()]. 
mapping(string:mixed) delete_file(string path, RequestID id) 
{ 
  // Fall back to find_file(). 
  RequestID tmp_id = id->close_me(); 
  tmp_id->not_query = query_location() + path; 
  tmp_id->method = "DELELE"; 
  // FIXME: Logging? 
  return find_file(path, id) || Roxen.http_status(404); 
} 
 
int(0..1) recurse_delete_files(string path, MultiStatus stat, RequestID id) 
{ 
  Stat st = stat_file(path, id); 
  if (!st) return 0; 
  if (st->isdir) { 
    // RFC 2518 8.6.2 
    //   The DELETE operation on a collection MUST act as if a 
    //   "Depth: infinity" header was used on it. 
    int(0..1) fail; 
    foreach(find_dir(path, id) || ({}), string fname) { 
      fail |= recurse_delete_files(path+"/"+fname, stat, id); 
    } 
    // RFC 2518 8.6.2 
    //   424 (Failed Dependancy) errors SHOULD NOT be in the 
    //   207 (Multi-Status). 
    if (fail) return fail; 
  } 
  mapping ret = delete_file(path, id); 
  if (ret->code != 204) { 
    // RFC 2518 8.6.2 
    //   Additionally 204 (No Content) errors SHOULD NOT be returned 
    //   in the 207 (Multi-Status). The reason for this prohibition 
    //   is that 204 (No COntent) is the default success code. 
    stat->add_response(path, XMLStatusNode(ret->code)); 
  } 
  return ret->code >= 300; 
} 
 
mapping copy_file(string path, string dest, int(-1..1) behavior, RequestID id) 
{ 
  werror("copy_file(%O, %O, %O, %O)\n", 
         path, dest, behavior, id); 
  return Roxen.http_status (Protocols.HTTP.HTTP_NOT_IMPL); 
} 
 
void recurse_copy_files(string path, int depth, string dest_prefix, 
                        string dest_suffix, 
                        mapping(string:int(-1..1)) behavior, 
                        MultiStatus result, RequestID id) 
{ 
  Stat st = stat_file(path, id); 
  if (!st) return; 
  if (!dest_prefix) { 
    Standards.URI dest_uri = Standards.URI(result->href_prefix); 
    Configuration c = roxen->find_configuration_for_url(dest_uri, id->conf); 
    // FIXME: Mounting server on subpath. 
    if (!c || 
        !has_prefix(dest_uri->path||"/", query_location())) { 
      // Destination is not local to this module. 
      // FIXME: Not supported yet. 
      result->add_response(dest_suffix, XMLStatusNode(502)); 
      return; 
    } 
    dest_prefix = (dest_uri->path||"/")[sizeof(query_location())..]; 
    Stat dest_st; 
    if (!(dest_st = stat_file(combine_path(dest_prefix, ".."), id)) || 
        !(dest_st->isdir)) { 
      result->add_response("", XMLStatusNode(409)); 
      return; 
    } 
    if (combine_path(dest_prefix, dest_suffix, ".") == 
        combine_path(path, ".")) { 
      result->add_response(dest_suffix, XMLStatusNode(403, "Source and destination are the same.")); 
      return; 
    } 
  } 
  werror("recurse_copy_files(%O, %O, %O, %O, %O, %O, %O)\n", 
         path, depth, dest_prefix, dest_suffix, behavior, result, id); 
  mapping res = copy_file(path, dest_prefix + dest_suffix, 
                          behavior[dest_prefix + dest_suffix]||behavior[0], 
                          id); 
  result->add_response(dest_suffix, XMLStatusNode(res->error, res->data)); 
  if (res->error >= 300) { 
    // RFC 2518 8.8.3 and 8.8.8 (error minimization). 
    return; 
  } 
  if ((depth <= 0) || !st->isdir) return; 
  depth--; 
  foreach(find_dir(path, id), string filename) { 
    recurse_copy_files(combine_path(path, filename), depth, 
                       dest_prefix, combine_path(dest_suffix, filename), 
                       behavior, result, id); 
  } 
} 
 
string real_file(string f, RequestID id){} 
 
void add_api_function( string name, function f, void|array(string) types) 
{ 
  _api_functions[name] = ({ f, types }); 
} 
 
mapping api_functions() 
{ 
  return _api_functions; 
} 
 
#if ROXEN_COMPAT <= 1.4 
mapping(string:function) query_tag_callers() 
//! Compat 
{ 
  mapping(string:function) m = ([]); 
  foreach(glob("tag_*", indices( this_object())), string q) 
    if(functionp( this_object()[q] )) 
      m[replace(q[4..], "_", "-")] = this_object()[q]; 
  return m; 
} 
 
mapping(string:function) query_container_callers() 
//! Compat 
{ 
  mapping(string:function) m = ([]); 
  foreach(glob("container_*", indices( this_object())), string q) 
    if(functionp( this_object()[q] )) 
      m[replace(q[10..], "_", "-")] = this_object()[q]; 
  return m; 
} 
#endif 
 
mapping(string:array(int|function)) query_simpletag_callers() 
{ 
  mapping(string:array(int|function)) m = ([]); 
  foreach(glob("simpletag_*", indices(this_object())), string q) 
    if(functionp(this_object()[q])) 
      m[replace(q[10..],"_","-")] = 
        ({ intp (this_object()[q + "_flags"]) && this_object()[q + "_flags"], 
           this_object()[q] }); 
  return m; 
} 
 
mapping(string:array(int|function)) query_simple_pi_tag_callers() 
{ 
  mapping(string:array(int|function)) m = ([]); 
  foreach (glob ("simple_pi_tag_*", indices (this_object())), string q) 
    if (functionp (this_object()[q])) 
      m[replace (q[sizeof ("simple_pi_tag_")..], "_", "-")] = 
        ({(intp (this_object()[q + "_flags"]) && this_object()[q + "_flags"]) | 
          RXML.FLAG_PROC_INSTR, this_object()[q]}); 
  return m; 
} 
 
RXML.TagSet query_tag_set() 
{ 
  if (!module_tag_set) { 
    array(function|program|object) tags = 
      filter (rows (this_object(), 
                    glob ("Tag*", indices (this_object()))), 
              lambda(mixed x) { return functionp(x)||programp(x); }); 
    for (int i = 0; i < sizeof (tags); i++) 
      if (programp (tags[i])) 
        if (!tags[i]->is_RXML_Tag) tags[i] = 0; 
        else tags[i] = tags[i](); 
      else { 
        tags[i] = tags[i](); 
        // Bogosity: The check is really a little too late here.. 
        if (!tags[i]->is_RXML_Tag) tags[i] = 0; 
      } 
    tags -= ({0}); 
    module_tag_set = 
      (this_object()->ModuleTagSet || RXML.TagSet) (this_object(), "", tags); 
  } 
  return module_tag_set; 
} 
 
mixed get_value_from_file(string path, string index, void|string pre) 
{ 
  Stdio.File file=Stdio.File(); 
  if(!file->open(path,"r")) return 0; 
  if(has_suffix(index, "()")) 
    index = index[..sizeof(index) - 3]; 
 
  //  Pass path to original file so that include statements for local files 
  //  work correctly. 
  return compile_string((pre || "") + file->read(), path)[index]; 
} 
 
static private mapping __my_tables = ([]); 
 
array(mapping(string:mixed)) sql_query( string query, mixed ... args ) 
//! Do a SQL-query using @[get_my_sql], the table names in the query 
//! should be written as &table; instead of table. As an example, if 
//! the tables 'meta' and 'data' have been created with create_tables 
//! or get_my_table, this query will work: 
//! 
//! SELECT &meta;.id AS id, &data;.data as DATA 
//!        FROM &data;, &meta; WHERE &my.meta;.xsize=200 
//! 
{ 
  return get_my_sql()->query( replace( query, __my_tables ), @args ); 
} 
 
object sql_big_query( string query, mixed ... args ) 
//! Identical to @[sql_query], but the @[Sql.sql()->big_query] method 
//! will be used instead of the @[Sql.sql()->query] method. 
{ 
  return get_my_sql()->big_query( replace( query, __my_tables ), @args ); 
} 
 
array(mapping(string:mixed)) sql_query_ro( string query, mixed ... args ) 
//! Do a read-only SQL-query using @[get_my_sql], the table names in the query 
//! should be written as &table; instead of table. As an example, if 
//! the tables 'meta' and 'data' have been created with create_tables 
//! or get_my_table, this query will work: 
//! 
//! SELECT &meta;.id AS id, &data;.data as DATA 
//!        FROM &data;, &meta; WHERE &my.meta;.xsize=200 
//! 
{ 
  return get_my_sql(1)->query( replace( query, __my_tables ), @args ); 
} 
 
object sql_big_query_ro( string query, mixed ... args ) 
//! Identical to @[sql_query_ro], but the @[Sql.sql()->big_query] method 
//! will be used instead of the @[Sql.sql()->query] method. 
{ 
  return get_my_sql(1)->big_query( replace( query, __my_tables ), @args ); 
} 
 
static int create_sql_tables( mapping(string:array(string)) definitions, 
                              string|void comment, 
                              int|void no_unique_names ) 
//! Create multiple tables in one go. See @[get_my_table] 
//! Returns the number of tables that were actually created. 
{ 
  int ddc; 
  if( !no_unique_names ) 
    foreach( indices( definitions ), string t ) 
      ddc+=get_my_table( t, definitions[t], comment, 1 ); 
  else 
  { 
    Sql.Sql sql = get_my_sql(); 
    foreach( indices( definitions ), string t ) 
    { 
      if( !catch { 
        sql->query("CREATE TABLE "+t+" ("+definitions[t]*","+")" ); 
      } ) 
        ddc++; 
      DBManager.is_module_table( this_object(), my_db, t, comment ); 
    } 
  } 
  return ddc; 
} 
 
static string sql_table_exists( string name ) 
//! Return the real name of the table 'name' if it exists. 
{ 
  if(strlen(name)) 
    name = "_"+name; 
   
  string res = hash(_my_configuration->name)->digits(36) 
    + "_" + replace(sname(),"#","_") + name; 
 
  return catch(get_my_sql()->query( "SELECT * FROM "+res+" LIMIT 1" ))?0:res; 
} 
 
 
static string|int get_my_table( string|array(string) name, 
                                void|array(string)|string definition, 
                                string|void comment, 
                                int|void flag ) 
//! @decl string get_my_table( string name, array(string) types ) 
//! @decl string get_my_table( string name, string definition ) 
//! @decl string get_my_table( string definition ) 
//! @decl string get_my_table( array(string) definition ) 
//! 
//! Returns the name of a table in the 'shared' database that is 
//! unique for this module. It is possible to select another database 
//! by using @[set_my_db] before calling this function. 
//! 
//! You can use @[create_sql_tables] instead of this function if you want 
//! to create more than one table in one go. 
//!  
//! If @[flag] is true, return 1 if a table was created, and 0 otherwise. 
//!  
//! In the first form, @[name] is the (postfix of) the name of the 
//! table, and @[types] is an array of definitions, as an example: 
//! 
//!  
//! @code{ 
//!   cache_table = get_my_table( "cache", ({ 
//!               "id INT UNSIGNED AUTO_INCREMENT", 
//!               "data BLOB", 
//!               }) ); 
//! @} 
//! 
//! In the second form, the whole table definition is instead sent as 
//! a string. The cases where the name is not included (the third and 
//! fourth form) is equivalent to the first two cases with the name "" 
//! 
//! If the table does not exist in the datbase, it is created. 
//! 
//! @note 
//!   This function may not be called from create 
// 
// If it exists, but it's definition is different, the table will be 
// altered with a ALTER TABLE call to conform to the definition. This 
// might not work if the database the table resides in is not a MySQL 
// database (normally it is, but it's possible, using @[set_my_db], 
// to change this). 
{ 
  string oname; 
  int ddc; 
  if( !definition ) 
  { 
    definition = name; 
    oname = name = ""; 
  } 
  else if(strlen(name)) 
    name = "_"+(oname = name); 
 
  Sql.Sql sql = get_my_sql(); 
 
  string res = hash(_my_configuration->name)->digits(36) 
    + "_" + replace(sname(),"#","_") + name; 
 
  if( !sql ) 
  { 
    report_error("Failed to get SQL handle, permission denied for "+my_db+"\n"); 
    return 0; 
  } 
  if( arrayp( definition ) ) 
    definition *= ", "; 
   
  if( catch(sql->query( "SELECT * FROM "+res+" LIMIT 1" )) ) 
  { 
    ddc++; 
    mixed error = 
      catch 
      { 
        get_my_sql()->query( "CREATE TABLE "+res+" ("+definition+")" ); 
        DBManager.is_module_table( this_object(), my_db, res, 
                                   oname+"\0"+comment ); 
      }; 
    if( error ) 
    { 
      if( strlen( name ) ) 
        name = " "+name; 
      report_error( "Failed to create table"+name+": "+ 
                    describe_error( error ) ); 
      return 0; 
    } 
    if( flag ) 
    { 
      __my_tables[ "&"+oname+";" ] = res; 
      return ddc; 
    } 
    return __my_tables[ "&"+oname+";" ] = res; 
  } 
//   // Update definition if it has changed. 
//   mixed error =  
//     catch 
//     { 
//       get_my_sql()->query( "ALTER TABLE "+res+" ("+definition+")" ); 
//     }; 
//   if( error ) 
//   { 
//     if( strlen( name ) ) 
//       name = " for "+name; 
//     report_notice( "Failed to update table definition"+name+": "+ 
//               describe_error( error ) ); 
//   } 
  if( flag ) 
  { 
    __my_tables[ "&"+oname+";" ] = res; 
    return ddc; 
  } 
  return __my_tables[ "&"+oname+";" ] = res; 
} 
 
static string my_db = "local"; 
 
static void set_my_db( string to ) 
//! Select the database in which tables will be created with 
//! get_my_table, and also the one that will be returned by 
//! @[get_my_sql] 
{ 
  my_db = to; 
} 
 
Sql.Sql get_my_sql( int|void read_only ) 
//! Return a SQL-object for the database set with @[set_my_db], 
//! defaulting to the 'shared' database. If read_only is specified, 
//! the database will be opened in read_only mode. 
//!  
//! See also @[DBManager.get] 
{ 
  return DBManager.cached_get( my_db, _my_configuration, read_only ); 
}