1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
/* Bugs by: Per */ 
/* 
 * name = "English language plugin "; 
 * doc = "Handles the conversion of numbers and dates to English. You have to restart the server for updates to take effect."; 
 */ 
 
inherit "abstract.pike"; 
 
constant cvs_version = "$Id$"; 
 
// English is a special case, since it is also the standard language... 
constant _id = ({ "en", "standard", "english" }); 
constant _aliases = ({ "en", "eng", "english" }); 
 
constant months = ({ 
  "January", "February", "March", "April", "May", 
  "June", "July", "August", "September", "October", 
  "November", "December" }); 
 
constant days = ({ 
  "Sunday","Monday","Tuesday","Wednesday", 
  "Thursday","Friday","Saturday" }); 
 
string ordered(int i) 
{ 
  switch(i) 
  { 
   case 0: 
    return "buggy"; 
   case 1: 
    return "1st"; 
   case 2: 
    return "2nd"; 
   case 3: 
    return "3rd"; 
   default: 
    if((i%100 > 10) && (i%100 < 14)) 
      return i+"th"; 
    if((i%10) == 1) 
      return i+"st"; 
    if((i%10) == 2) 
      return i+"nd"; 
    if((i%10) == 3) 
      return i+"rd"; 
    return i+"th"; 
  } 
} 
 
string date(int timestamp, mapping|void m) 
{ 
  mapping t1=localtime(timestamp); 
  mapping t2=localtime(time(0)); 
 
  if(!m) m=([]); 
 
  if(!(m["full"] || m["date"] || m["time"])) 
  { 
    if(t1["yday"] == t2["yday"] && t1["year"] == t2["year"]) 
      return "today, "+ ctime(timestamp)[11..15]; 
 
    if(t1["yday"]+1 == t2["yday"] && t1["year"] == t2["year"]) 
      return "yesterday, "+ ctime(timestamp)[11..15]; 
 
    if(t1["yday"]-1 == t2["yday"] && t1["year"] == t2["year"]) 
      return "tomorrow, "+ ctime(timestamp)[11..15]; 
 
    if(t1["year"] != t2["year"]) 
      return (month(t1["mon"]+1) + " " + (t1["year"]+1900)); 
    return (month(t1["mon"]+1) + " " + ordered(t1["mday"])); 
  } 
  if(m["full"]) 
    return ctime(timestamp)[11..15]+", "+ 
           month(t1["mon"]+1) + " the " 
           + ordered(t1["mday"]) + ", " +(t1["year"]+1900); 
  if(m["date"]) 
    return month(t1["mon"]+1) + " the "  + ordered(t1["mday"]) 
      + " in the year of " +(t1["year"]+1900); 
  if(m["time"]) 
    return ctime(timestamp)[11..15]; 
} 
 
 
string number(int num) 
{ 
  if(num<0) 
    return "minus "+number(-num); 
  switch(num) 
  { 
   case 0:  return ""; 
   case 1:  return "one"; 
   case 2:  return "two"; 
   case 3:  return "three"; 
   case 4:  return "four"; 
   case 5:  return "five"; 
   case 6:  return "six"; 
   case 7:  return "seven"; 
   case 8:  return "eight"; 
   case 9:  return "nine"; 
   case 10: return "ten"; 
   case 11: return "eleven"; 
   case 12: return "twelve"; 
   case 13: return "thirteen"; 
   case 14: return "fourteen"; 
   case 15: return "fifteen"; 
   case 16: return "sixteen"; 
   case 17: return "seventeen"; 
   case 18: return "eighteen"; 
   case 19: return "nineteen"; 
   case 20: return "twenty"; 
   case 30: return "thirty"; 
   case 80: return "eighty"; 
   case 40: 
    return "forty"; 
   case 60: case 70: case 90: 
     return number(num/10)+"ty"; 
   case 50: return "fifty"; 
   case 21..29: case 31..39: 
   case 51..59: case 61..69: case 71..79: 
   case 81..89: case 91..99: case 41..49: 
     return number((num/10)*10)+number(num%10); 
   case 100: case 200: case 300: case 400: case 500: 
   case 600: case 700: case 800: case 900: 
     return number(num/100)+" hundred"; 
   case 101..199: case 201..299: case 301..399: case 401..499: 
   case 501..599: case 601..699: case 701..799: case 801..899: 
   case 901..999: 
     return number(num/100)+" hundred and "+number(num%100); 
   case 1001..1099: 
     return number(num/1000)+" thousand and "+number(num%1000); 
   case 1000: case 1100..999999: 
     return number(num/1000)+" thousand "+number(num%1000); 
   case 1000001..1000099: 
     return number(num/1000000)+" million and "+number(num%1000000); 
   case 1000000: case 1000100..999999999: 
     return number(num/1000000)+" million "+number(num%1000000); 
   default: 
    return "many"; 
  } 
} 
 
 
void create() 
{ 
  roxen.dump( __FILE__ ); 
}