1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
/* This file is executed by Pike to bootstrap Roxen on NT. 
 * 
 * $Id$ 
 */ 
 
string dir; 
string log_dir; 
string key; 
 
class Options 
{ 
  int redirect = 0; // Default is not to redirect stdout with friends. 
  int verbose = 1; 
  array(string) script; 
  string wd; 
} 
 
function werror = predef::werror; 
 
object _roxen; 
object roxen() 
{ 
  if(!_roxen) 
    _roxen =  all_constants()["roxen"]; 
  return _roxen; 
} 
 
int write_status_file() 
{ 
  call_out(write_status_file, 30); 
 
  Stdio.File fd = Stdio.File(); 
  if(fd->open(log_dir+"/status", "wct")) 
  { 
    if( roxen() ) 
    { 
      foreach(roxen()->configurations, object c) 
        // Configuration not usable here 
        fd->write(c->query_name()+"\r\n"+ 
                  c->query("MyWorldLocation")+"\r\n"); 
      fd->close(); 
    } 
  } else { 
    werror("Failed to open status file %s.\n", log_dir + "/status"); 
    return 0; 
  } 
  return 1; 
} 
 
function mw; 
void my_werror(string fmt, mixed ... args) 
{ 
  if(sizeof(args)) 
    mw(sprintf(fmt, @args)); 
  else 
    mw(fmt); 
} 
 
void read_from_stdin() 
{ 
  while(!file_stat(key)) sleep(2); 
  rm(key); 
 
  //  Ask for orderly shutdown. The signal has potentially already been 
  //  delivered but it doesn't hurt to make sure. 
  if (object rxn = roxen()) { 
    if (!rxn->is_shutting_down()) 
      rxn->exit_when_done(); 
  } 
  sleep(60); 
  werror("Roxen not shutting down nicely... forcing termination\n"); 
  exit(0); 
} 
 
string pathcnv (string path) 
// Convert a path to use '/' as dir separator. Roxen always uses '/' 
// for that (even on NT). 
{ 
  return path && replace (path, "\\", "/"); 
} 
 
string getcwd() 
{ 
  return pathcnv (predef::getcwd()); 
} 
 
int main(int argc, array (string) argv) 
{ 
  add_constant ("getcwd", getcwd); 
 
  Options opt = Options(); 
   
  if(argc > 1 && sizeof(argv[1]) && argv[1][0]=='+') 
  { 
    key = combine_path (getcwd(), argv[1][1..]); 
    argv = argv[..0] + argv[2..]; 
    argc--; 
  } 
 
  if(argc > 1 && argv[1] == "-silent") 
  { 
    opt->redirect = 1; 
    argv = argv[..0] + argv[2..]; 
    argc--; 
  } 
   
  int i = search (argv, "--program"); 
  if (i >= 0) { 
    opt->script = argv[i+1..]; 
    argv = argv[..i-1]; 
  } 
 
  foreach(Getopt.find_all_options(argv, ({ 
    ({ "cd", Getopt.HAS_ARG, ({ "--cd" }) }), 
    ({ "quiet", Getopt.NO_ARG, ({ "-q", "--quiet" }) }) 
  })), array arg) 
    switch(arg[0]) 
    { 
      case "cd": 
        opt->wd = arg[1]; 
        break; 
         
      case "quiet": 
        opt->verbose = 0; 
        break; 
    } 
  // Don't complain about unknown options but 
  // remove NULL entries left behind by find_all_options 
  argv -= ({ 0 }); 
 
  dir = pathcnv (combine_path(getcwd(),__FILE__ + "/..")); 
  log_dir = combine_path (dir, "../logs"); 
 
  if(!cd(dir)) 
  { 
    werror("Failed to cd to "+dir+"\n"); 
    exit(0); 
  } 
  add_module_path( dir+"/etc/modules" ); 
  add_include_path( dir+"/etc/include" ); 
 
  add_include_path( dir+"/base_server" ); 
  add_program_path( dir+"/base_server" ); 
 
  add_include_path( dir ); 
  add_program_path( dir ); 
 
 
  Stdio.File fd = Stdio.File(); 
 
  mkdir(log_dir); 
 
  if(opt->redirect) 
  { 
    mkdir(log_dir+"/debug"); 
 
    if (!opt->script) { 
      rm(log_dir+"/debug/default.10"); 
      for(int i=9;i>0;i--) 
        mv(log_dir+"/debug/default."+i, log_dir+"/debug/default."+(i+1)); 
    } 
 
    if(fd->open(log_dir+"/debug/default.1", "wct")) 
    { 
      fd->dup2( Stdio.stderr ); 
      fd->dup2( Stdio.stdout ); 
      mw = fd->write; 
      add_constant("werror", my_werror); 
      add_constant("write", my_werror); 
      werror = my_werror; 
    } else { 
      werror("Failed to do redirection to %s.\n", log_dir+"/debug/default.1"); 
    } 
  } 
 
  if(opt->verbose) 
    werror("Roxen base directory : "+dir+"\n" 
           "Roxen log directory  : "+log_dir+"\n" 
           "Roxen shutdown file  : "+(key || "None")+"\n" 
           "Roxen arguments      : "+(sizeof(argv)>1?argv[1..]*" ":"None")+"\n" 
#if constant (Nettle) 
         "This version of Roxen has crypto algorithms available.\n" 
#endif 
         ); 
 
  call_out (write_status_file, 1); 
   
  if(key) thread_create(read_from_stdin); 
  
  if(opt->wd) 
    cd(opt->wd); 
 
  if(opt->script) 
    argv = opt->script; 
  else 
    argv[0] = dir+"/base_server/roxenloader.pike"; 
 
  return ((program)(argv[0]))()->main(argc, argv); 
}