1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
220
  
221
  
222
  
223
  
224
  
225
  
226
  
227
  
228
  
229
  
230
  
231
  
232
  
233
  
234
  
235
  
236
  
237
  
238
  
239
  
240
  
241
  
242
  
243
  
244
  
245
  
246
  
247
  
248
  
249
  
250
  
251
  
252
  
253
  
254
  
255
  
256
  
257
  
258
  
259
  
260
  
261
  
262
  
263
  
264
  
265
  
266
  
267
  
268
  
269
  
270
  
271
  
272
  
273
  
274
  
275
  
276
  
277
  
278
  
279
  
280
  
281
  
282
  
283
  
284
  
285
  
286
  
287
  
288
  
289
  
290
  
291
  
292
  
293
  
294
  
295
  
296
  
297
  
298
  
299
  
300
  
301
  
302
  
303
  
304
  
305
  
306
  
307
  
308
  
309
  
310
  
311
  
312
  
313
  
314
  
315
  
316
  
317
  
318
  
319
  
320
  
321
  
322
  
323
  
324
  
325
  
326
  
327
  
328
  
329
  
330
  
331
  
332
  
333
  
334
  
335
  
336
  
337
  
338
  
339
  
340
  
341
  
342
  
343
  
344
  
345
  
346
  
347
  
348
  
349
  
350
  
351
  
352
  
353
  
354
  
355
  
356
  
357
  
358
  
359
  
360
  
361
  
362
  
363
  
364
  
365
  
366
  
367
  
368
  
369
  
370
  
371
  
372
  
373
  
374
  
375
  
376
  
377
  
378
  
379
  
380
  
381
  
382
  
383
  
384
  
385
  
386
  
387
  
388
  
389
  
390
  
391
  
392
  
393
  
394
  
395
  
396
  
397
  
398
  
399
  
400
  
401
  
402
  
403
  
404
  
405
  
406
  
407
  
408
  
409
  
410
  
411
  
412
  
413
  
414
  
415
  
416
  
417
  
418
  
419
  
420
  
421
  
422
  
423
  
424
  
425
  
426
  
427
  
428
  
429
  
430
  
431
  
432
  
433
  
434
  
435
  
436
  
437
  
438
  
439
  
440
  
441
  
442
  
443
  
444
  
445
  
446
  
447
  
448
  
449
  
450
  
451
  
452
  
453
  
454
  
455
  
456
  
457
  
458
  
459
  
460
  
461
  
462
  
463
  
464
  
465
  
466
  
467
  
468
  
469
  
470
  
471
  
472
  
473
  
474
  
475
  
476
  
477
  
478
  
479
  
480
  
481
  
482
  
483
  
484
  
485
  
486
  
487
  
488
  
489
  
490
  
491
  
492
  
493
  
494
  
495
  
496
  
497
  
498
  
499
  
500
  
501
  
502
  
503
  
504
  
505
  
506
  
507
  
508
  
509
  
510
  
511
  
512
  
513
  
514
  
515
  
516
  
517
  
518
  
519
  
520
  
521
  
522
  
523
  
524
  
525
  
526
  
527
  
528
  
529
  
530
  
531
  
532
  
533
  
534
  
535
  
536
  
537
  
538
  
539
  
540
  
541
  
542
  
543
  
544
  
545
  
546
  
547
  
548
  
549
  
550
  
551
  
552
  
553
  
554
  
555
  
556
  
557
  
558
  
559
  
560
  
561
  
562
  
563
  
564
  
565
  
566
  
567
  
568
  
569
  
570
  
571
  
572
  
573
  
574
  
575
  
576
  
577
  
578
  
579
  
580
  
581
  
582
  
583
  
584
  
585
  
586
  
587
  
588
  
589
  
590
  
591
  
592
  
593
  
594
  
595
  
596
  
597
  
598
  
599
  
600
  
601
  
602
  
603
  
604
  
605
  
606
  
607
  
608
  
609
  
610
  
611
  
612
  
613
  
614
  
615
  
616
  
617
  
#! /usr/bin/env pike 
 
mapping(string:program) hooks = ([ 
  "pre-commit" : PreCommitHook, 
  "pre-receive" : PreReceiveHook, 
]); 
 
mapping(string:program) filters = ([ 
#if 0 
  "nice_ident" : NiceIdentFilter, 
#endif 
]); 
 
 
 
constant filterops = ({ "clean", "smudge" }); 
 
void fail(string msg, mixed ... args) 
{ 
  werror(msg, @args); 
  exit(1); 
} 
 
void iofailn(int errno, string msg, mixed ... args) 
{ 
  fail(msg+": %s\n", @args, strerror(errno)); 
} 
 
void iofail(string msg, mixed ... args) 
{ 
  iofailn(errno(), msg, @args); 
} 
 
array(string) split_z(string data) 
{ 
  array(string) a = data / "\0"; 
  if (sizeof(a) && a[-1] == "") 
    a = a[..sizeof(a)-2]; 
  return a; 
} 
 
string run_git_ex(int max_exitcode, string ... args) 
{ 
  mapping res = Process.run(({"git"})+args); 
  if (res->exitcode > max_exitcode) { 
    werror(res->stderr); 
    fail("git exited with code %d\n", res->exitcode); 
  } 
  return res->stdout; 
} 
 
string run_git(string ... args) 
{ 
  return run_git_ex(0, @args); 
} 
 
string get_staged_file(string filename) 
{ 
  string sha; 
  if (2 != sscanf(run_git("ls-files", "--stage", "--", filename), 
                  "%*o %s ", sha)) 
    fail("Unable to parse output from git ls-files...\n"); 
  return run_git("cat-file", "blob", sha); 
} 
 
string get_committed_file(string sha, string filename) 
{ 
  string blob; 
  string attrentry = run_git("ls-tree", sha, "--", filename); 
  if (2 != sscanf(attrentry, "%*o blob %s\t", blob)) 
    fail("Unexpected output from git ls-tree\n"); 
  return run_git("cat-file", "blob", blob); 
} 
 
class GitAttributes 
{ 
  enum { 
    ATTR_TRUE = 1, 
    ATTR_FALSE = 2, 
    ATTR_UNSET = 3 
  }; 
 
  class AttrState(string attr, string|int setto) { 
    static string _sprintf(int type) { 
      return type=='O' && sprintf("AttrState(%O, %O)\n", attr, setto); 
    } 
  }; 
 
  class MatchAttr(string name, int is_macro, array(AttrState) states) { 
    static string _sprintf(int type) { 
      return type=='O' && sprintf("MatchAttr(%O, %d, %O)\n", 
                                  name, is_macro, states); 
    } 
  }; 
 
  static array(MatchAttr) attrs = ({}); 
 
  static int invalid_attr_name(string name) 
  { 
    int n; 
    if(name == "" || name[0] == '-') 
      return 1; 
    sscanf(name, "%*[-._0-9a-zA-Z]%n", n); 
    return n != sizeof(name); 
  } 
 
  static AttrState parse_attr(string src) 
  { 
    string equals = 0; 
    string|int setto; 
    sscanf(src, "%s=%s", src, equals); 
    if(src[0] == '-' || src[0] == '!') { 
      setto = (src[0]=='-'? ATTR_FALSE : ATTR_UNSET); 
      src = src[1..]; 
    } else 
      setto = equals || ATTR_TRUE; 
    if(invalid_attr_name(src)) 
      fail("%s is not a valid attribute name\n", src); 
    return AttrState(src, setto); 
  } 
 
  static MatchAttr parse_attr_line(string line, int macro_ok) 
  { 
    int is_macro=0; 
    string name; 
    line = String.trim_whites(replace(line, ({"\t","\r","\n"}), 
                                      ({" ", " ", " "}))); 
    if(!sizeof(line) || line[0] == '#') 
      return 0; 
    if(has_prefix(line, "[attr]")) { 
      if(!macro_ok) 
        fail("%s not allowed\n", name); 
      is_macro=1; 
      sscanf(line, "[attr]%*[ ]%s%*[ ]%s", name, line); 
    } else { 
      sscanf(line, "%s%*[ ]%s", name, line); 
    } 
    return MatchAttr(name, is_macro, map(line/" "-({""}), parse_attr)); 
  } 
 
  static void handle_attr_line(string line, int macro_ok) 
  { 
    MatchAttr a = parse_attr_line(line, macro_ok); 
    if(a) attrs += ({ a }); 
  } 
 
  static void create(string data) 
  { 
    foreach(data/"\n", string line) 
      handle_attr_line(line, 1); 
  } 
 
  static int path_matches(string path, string pattern) 
  { 
    if(search(pattern, "/")<0) 
      return glob(pattern, (path/"/")[-1]); 
    if(has_prefix(pattern, "/")) 
      pattern = pattern[1..]; 
    return glob(pattern, path); 
  } 
 
  static void macroexpand_one(string attrname, array(MatchAttr) attrs, 
                              mapping(string:string|int) all_attr) 
  { 
    MatchAttr a = 0; 
    if(all_attr[attrname] != ATTR_TRUE) 
      return; 
    for(int i=sizeof(attrs)-1; i>=0; --i) 
      if(attrs[i]->is_macro && attrs[i]->name == attrname) 
        a = attrs[i]; 
    if(a) fill_one(a, attrs, all_attr); 
  } 
 
  static void fill_one(MatchAttr attr, array(MatchAttr) attrs, 
                       mapping(string:string|int) all_attr) 
  { 
    for(int i = sizeof(attr->states)-1; i>=0; --i) { 
      AttrState s = attr->states[i]; 
      if(!all_attr[s->attr]) { 
        all_attr[s->attr] = s->setto; 
        macroexpand_one(s->attr, attrs, all_attr); 
      } 
    } 
  } 
 
  static void fill(string path, array(MatchAttr) attrs, 
                   mapping(string:string|int) all_attr) 
  { 
    for(int i=sizeof(attrs)-1; i>=0; --i) 
      if(!attrs[i]->is_macro && path_matches(path, attrs[i]->name)) 
        fill_one(attrs[i], attrs, all_attr); 
  } 
 
  mapping(string:string|int) checkattr(string path) 
  { 
    mapping(string:string|int) all_attr = ([]); 
    fill(path, attrs, all_attr); 
    return all_attr; 
  } 
 
  static string _sprintf(int type) { 
    return type=='O' && sprintf("GitAttributes(%O)\n", attrs); 
  } 
} 
 
 
 
/* Hooks */ 
 
class CommitHookUtils 
{ 
  int find_expanded_ident(string data) 
  { 
    int p=0; 
    while ((p = search(data, "$Id", p))>=0) { 
      if (data[p..p+3] != "$Id$") 
        return 1; 
      p += 4; 
    } 
    return 0; 
  } 
   
  int find_expanded_ident_in_staged_file(string filename) 
  { 
    return find_expanded_ident(get_staged_file(filename)); 
  } 
   
  int find_expanded_ident_in_committed_file(string sha, string filename) 
  { 
    return find_expanded_ident(get_committed_file(sha, filename)); 
  } 
} 
 
/* Checks run before editing a commit message */ 
 
class PreCommitHook 
{ 
  inherit CommitHookUtils; 
 
  int check_attributes_staged() 
  { 
    // We don't allow .gitattributes to differ between wt and index, 
    // because that could mean the committed stuff ends up with different 
    // attributes than they have right now... 
 
    if (sizeof(run_git("diff", "--name-only", ".gitattributes"))) { 
      write("You have unstaged changes to .gitattributes.\n" 
            "Please add or stash them before commit.\n"); 
      return 1; 
    } 
  } 
 
  int check_ident(string filename) 
  { 
    if (find_expanded_ident_in_staged_file(filename)) { 
        write("File %s contains an expanded ident.\n" 
              "Try 'git reset %s; git add %s', " 
              "or remove the ident manually.\n", 
              @({filename})*3); 
        return 1; 
    } 
    return 0; 
  } 
 
  int check_blocker_attributes(array(string) files_to_commit) 
  { 
    constant attrs_to_check = ({ "foreign_ident",  "block_commit", "ident" }); 
    foreach(run_git("check-attr", @attrs_to_check, 
                    "--", @files_to_commit) / "\n" - ({""}), 
            string line) { 
      array(string) parts = line / ": "; 
      if (sizeof(parts) != 3) 
        fail("Unexpected output from git check-attr, please fix check_blocker_attributes()\n"); 
      [string filename, string attribute, string value] = parts; 
      if (value != "unspecified") { 
        switch (attribute) { 
        case "foreign_ident": 
          write("File %s has the foreign_ident attribute.  Please remove it before commit.\n", filename); 
          return 1; 
        case "block_commit": 
          write("File %s is blocked from committing: %s\n", filename, 
                replace(value, "-", " ")); 
          return 1; 
        case "ident": 
          if (value == "unset") 
            break; 
          if (check_ident(filename)) 
            return 1; 
          break; 
        } 
      } 
    } 
    return 0; 
  } 
 
  int check_gitattributes_files(array(string) files_to_commit) 
  { 
    foreach(files_to_commit, string filename) 
      if(has_suffix(filename, "/.gitattributes")) { 
        write(".gitattributes are not allowed in subdirectories\n"); 
        return 1; 
      } 
         
    if(search(files_to_commit, ".gitattributes")>=0) { 
      string diff = run_git("diff", "-p", "--cached", 
                            "--", ".gitattributes"); 
      if (sizeof(diff)) { 
        int pos = search(diff, "\n@@"); 
        if (pos >= 0) 
          diff = diff[pos+1..]; 
        foreach(diff/"\n", string line) 
          if(sizeof(line) && search(line, "foreign_ident")>=0 && 
             search(line, "[attr]") != 1 && 
             (line[0]=='+' || line[0]=='-')) { 
            int code, len; 
            string fn; 
            if(sscanf(line, "%c/%s foreign_ident%n", code, fn, len) != 3 || 
               len != sizeof(line)) { 
              write("Unsupported change of foreign_ident in .gitattributes\n"); 
              return 1; 
            } 
            if (code=='-' && search(files_to_commit, fn)<0) { 
              write("Removed foreign_ident from unstaged file %s\n", fn); 
              return 1; 
            } 
          } 
      } 
    } 
    return 0; 
  } 
 
  int hook() 
  { 
    array(string) files_to_commit = 
      split_z(run_git("diff", "--staged", "--name-only", "-z")); 
    return 
      check_attributes_staged() || 
      check_blocker_attributes(files_to_commit) || 
      check_gitattributes_files(files_to_commit); 
  } 
} 
 
/* Checks run before accepting a push */ 
 
class PreReceiveHook 
{ 
  inherit CommitHookUtils; 
 
  int check_ident(string sha, string filename) 
  { 
    if (find_expanded_ident_in_committed_file(sha, filename)) { 
      write("File %s contains an expanded ident.\n", filename); 
      return 1; 
    } 
    return 0; 
  } 
 
  int check_blocker_attributes(string sha, GitAttributes attrs, array(string) files_to_commit) 
  { 
    foreach(files_to_commit, string filename) { 
      mapping(string:string|int) a = attrs->checkattr(filename); 
      if(a->foreign_ident == GitAttributes.ATTR_TRUE) { 
        write("File %s has the foreign_ident attribute.  Please remove it before commit.\n", filename); 
        return 1; 
      } 
      if(stringp(a->block_commit) || a->block_commit == GitAttributes.ATTR_TRUE) { 
        write("File %s is blocked from committing: %s\n", filename, 
              replace((stringp(a->block_commit)? a->block_commit : 
                       "no explanation given"), "-", " ")); 
          return 1; 
      } 
      if(a->ident && a->ident != GitAttributes.ATTR_FALSE && 
         a->ident != GitAttributes.ATTR_UNSET) { 
        if (check_ident(sha, filename)) 
          return 1; 
      } 
    } 
    return 0; 
  } 
 
  int check_gitattributes_files(string sha, array(string) files_to_commit) 
  { 
    foreach(files_to_commit, string filename) 
      if(has_suffix(filename, "/.gitattributes")) { 
        write(".gitattributes are not allowed in subdirectories\n"); 
        return 1; 
      } 
 
    if(search(files_to_commit, ".gitattributes")>=0) { 
      string diff = run_git("diff", "-p", sha+"^", sha, 
                            "--", ".gitattributes"); 
      if (sizeof(diff)) { 
        int pos = search(diff, "\n@@"); 
        if (pos >= 0) 
          diff = diff[pos+1..]; 
        foreach(diff/"\n", string line) 
          if(sizeof(line) && search(line, "foreign_ident")>=0 && 
             search(line, "[attr]") != 1 && 
             (line[0]=='+' || line[0]=='-')) { 
            int code, len; 
            string fn; 
            if(sscanf(line, "%c/%s foreign_ident%n", code, fn, len) != 3 || 
               len != sizeof(line)) { 
              write("Unsupported change of foreign_ident in .gitattributes\n"); 
              return 1; 
            } 
            if (code=='-' && search(files_to_commit, fn)<0) { 
              write("Removed foreign_ident from unstaged file %s\n", fn); 
              return 1; 
            } 
          } 
      } 
    } 
    return 0; 
  } 
 
  int check_commit(string sha) 
  { 
    write("Checking commit %s\n", sha); 
    array(string) committed_files = 
      split_z(run_git("diff", "--name-only", "-z", sha, sha+"^")); 
    string attrentry = run_git("ls-tree", sha, "--", ".gitattributes"); 
    string attrtext = ""; 
    if (sizeof(attrentry)) { 
      string blob; 
      if (2 != sscanf(attrentry, "%*o blob %s\t", blob)) 
        fail("Unexpected output from git ls-tree\n"); 
      attrtext = run_git("cat-file", "blob", blob); 
    } 
    GitAttributes attrs = GitAttributes(attrtext); 
    return check_blocker_attributes(sha, attrs, committed_files) || 
      check_gitattributes_files(sha, committed_files); 
  } 
 
  int check_push(string old_sha, string new_sha, string ref_name) 
  { 
    if(old_sha == "0"*40) { 
      // New ref, maybe check if the name is allowed... 
      return 0; 
    } else { 
      foreach(run_git("rev-list", old_sha+".."+new_sha)/"\n", string sha) 
        if(sizeof(sha) && check_commit(sha)) 
          return 1; 
      return 0; 
    } 
  } 
 
  int hook() 
  { 
    foreach(Stdio.stdin->read() / "\n", string line) 
      if(sizeof(line)) { 
        array(string) args = line / " "; 
        if(sizeof(args) != 3) 
          fail("Unexpected input line to pre-receive hook: %s\n", line); 
        if(check_push(@args)) 
          return 1; 
      } 
    return 0; 
  } 
} 
 
/* Filters */ 
 
/* A sample filter, not really useful... */ 
 
class NiceIdentFilter 
{ 
  static string replace_id(string f, function(string:string) replace) { 
    int p=0; 
    while((p=search(f, "$Id", p)) >= 0) { 
      int p2 = search(f, "$", p+3), p3 = search(f, "\n", p+3); 
      if (p2 > p && p2 < p3) { 
        string r = replace(f[p..p2]); 
        if (r) { 
          // werror("Replacing %O with %O\n", f[p..p2], r); 
          f = f[..p-1]+r+f[p2+1..]; 
          p += sizeof(r); 
        } else { 
          // werror("Not replacing %O\n", f[p..p2]); 
          p = p2+1; 
        } 
      } else p += 3; 
    } 
    return f; 
  } 
 
  static string clean_ident(string i) 
  { 
    if(has_prefix(i, "$Id:") && sizeof(i/" ")==13) 
      return "$Id$"; 
  } 
  
  static string smudge_ident(string i) 
  { 
    return "$Id$"; 
  } 
 
  int clean() 
  { 
    write(replace_id(Stdio.stdin->read(), clean_ident)); 
    return 0; 
  } 
 
  int smudge() 
  { 
    write(replace_id(Stdio.stdin->read(), smudge_ident)); 
    return 0; 
  } 
} 
 
/* Main helper */ 
 
class GitHelper 
{ 
  void setup_hooks() 
  { 
    constant hooksdir = "hooks"; 
    if (!sizeof(hooks)) 
      return; 
    if (!file_stat(hooksdir)) { 
      write("Creating the hooks directory\n"); 
      if (!mkdir(hooksdir)) 
        iofail("Failed to create %s", hooksdir); 
    } 
    foreach (hooks; string name; ) { 
      string path = combine_path(hooksdir, name); 
      Stdio.Stat s = file_stat(path, 1); 
      if (!s) { 
        write("Installing %s\n", path); 
        System.symlink(__FILE__, path); 
      } else if (s->islnk) { 
        /* Already setup ok, it seems */ 
      } else { 
        write("Hook %s already exists, so won't overwrite it...\n", name); 
      } 
    } 
  } 
 
  void setup_filter(string name, string op) 
  { 
    string confname = "filter."+name+"."+op; 
    string old = String.trim_all_whites(run_git_ex(1, "config", "--get", confname)); 
    string cmd = __FILE__+" filter_"+name+"_"+op; 
    if (old == "") { 
      write("Installing filter operation %s\n", confname); 
      run_git("config", confname, cmd); 
    } else if(old == cmd) { 
      /* Already has correct value */ 
    } else { 
      write("Filter operation %s is already set to %s, not modifying\n", 
            confname, old); 
    } 
  } 
 
  void setup_filters() 
  { 
    foreach (filters; string name; program fprog) { 
      object filter = fprog(); 
      foreach (filterops; ; string op) 
        if (filter[op]) 
          setup_filter(name, op); 
    } 
  } 
 
  int setup(array(string) args) 
  { 
    if (sizeof(args)) { 
      werror("githelper.pike should be invoked without arguments...\n"); 
      return 1; 
    } 
    if (!cd(String.trim_all_whites(run_git("rev-parse", "--git-dir")))) 
      iofail("Failed to cd to .git directory"); 
    setup_hooks(); 
    setup_filters(); 
    return 0; 
  } 
} 
 
string get_filter_op(string arg) 
{ 
  if (!has_prefix(arg, "filter_")) 
    return 0; 
  foreach (filterops; ; string op) 
    if (has_suffix(arg, "_"+op)) 
      return op; 
  return 0; 
} 
 
int main(int argc, array(string) argv) 
{ 
  string command_name = basename(argv[0]); 
  if (hooks[command_name]) 
    return hooks[command_name]()->hook(@argv[1..]); 
  else if (command_name == "githelper.pike") { 
    string fop; 
    if (argc>1 && (fop = get_filter_op(argv[1]))) { 
      string filter = argv[1][7..sizeof(argv[1])-(sizeof(fop)+2)]; 
      if (filters[filter]) { 
        object f = filters[filter](); 
        if (!f[fop]) { 
          werror("Filter %s does not implement %s!\n", filter, fop); 
          return 1; 
        } else 
          return f[fop](@argv[2..]); 
      } else { 
        werror("Unknown filter %s!\n", filter); 
        return 1; 
      } 
    } else 
      return GitHelper()->setup(argv[1..]); 
  } else { 
    werror("Unknown invocation method %s!\n", command_name); 
    return 1; 
  } 
}