1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
220
  
221
  
222
  
223
  
224
  
225
  
226
  
227
  
228
  
229
  
230
  
231
  
232
  
233
  
234
  
// Compatibility namespace 
 
#pike 8.1 
 
//! Pike 8.0 compatibility. 
//! 
//! The symbols in this namespace will appear in 
//! programs that use @tt{#pike 8.0@} or lower. 
 
//! @decl inherit predef:: 
 
object master() 
{ 
  return __REAL_VERSION__::master()->get_compat_master(8, 0); 
} 
 
#pragma no_deprecation_warnings 
 
//! Wrapper for iterators that implements the 8.0 and 
//! earlier iterator API. 
protected class Iterator 
{ 
  protected predef::Iterator it; 
 
  protected mixed index_value; 
 
  protected void create(predef::Iterator it) 
  { 
    this::it = it; 
    index_value = iterator_next(it); 
  } 
 
  protected int(0..1) `!() 
  { 
    return undefinedp(index_value); 
  } 
 
  int(0..1) next() 
  { 
    index_value = iterator_next(it); 
    return !undefinedp(index_value); 
  } 
 
  mixed index() 
  { 
    catch { 
      return iterator_index(it); 
    }; 
    return index_value; 
  } 
 
  mixed value() 
  { 
    catch { 
      return iterator_value(it); 
    }; 
    return index_value; 
  } 
 
  // 
  // Optional identifiers from this point onwards. 
  // 
 
  protected int _sizeof() 
  { 
    return sizeof(it); 
  } 
 
  protected void _random() 
  { 
    random(it); 
 
    index_value = iterator_next(it); 
  } 
 
  protected int(0..1) internal_first() 
  { 
    if (it->first) { 
      it->first(); 
    } 
 
    index_value = iterator_next(it); 
 
    return !undefinedp(index_value); 
  } 
 
  protected function(:mixed)|zero `first() 
  { 
    if (it->first) return internal_first; 
    return UNDEFINED; 
  } 
 
  protected void internal_set_index(mixed index) 
  { 
    if (it->set_index) { 
      it->set_index(index); 
    } 
 
    index_value = iterator_next(it); 
  } 
 
  protected function(mixed:void)|zero `set_index() 
  { 
    if (it->set_index) return internal_set_index; 
    return UNDEFINED; 
  } 
} 
 
#pragma deprecation_warnings 
 
protected Iterator get_iterator(mixed x) 
{ 
  return Iterator(predef::get_iterator(x)); 
} 
 
//! @decl void _assembler_debug() 
//! 
//! @deprecated Debug.assembler_debug 
 
//! @decl int _debug(int d) 
//! 
//! @deprecated Debug.debug 
 
//! @decl void _dump_program_tables(program p, int|void i) 
//! 
//! @deprecated Debug.dump_program_tables 
 
//! @decl int _optimizer_debug(int d) 
//! 
//! @deprecated Debug.optimizer_debug 
 
//! @decl int _map_all_objects(function f) 
//! 
//! @deprecated Debug.map_all_objects 
 
//! @decl int _refs(mixed x) 
//! 
//! @deprecated Debug.refs 
 
//! @decl mixed _next(mixed x) 
//! 
//! @deprecated Debug.next 
 
//! @decl mixed _prev(mixed x) 
//! 
//! @deprecated Debug.prev 
 
//! @decl object next_object(object o) 
//! 
//! @deprecated Debug.next_object 
 
protected int|array(string) _glob(string|array(string) a, string|array(string) b) 
{ 
  mapping r = ([ 
    "[" : "\\[", 
    "\\" : "\\\\" 
  ]); 
  if( stringp(a) ) 
    a = replace(a, r); 
  else 
    a = replace(a[*], r); 
  return 8.1::glob(a,b); 
} 
 
protected int(0..1) glob(string a, string b) 
{ 
  return _glob(a,b); 
} 
variant protected int(0..1) glob(array(string) a, string b) 
{ 
  return !!_glob(a,b); 
} 
variant protected array(string) glob(array(string)|string a, array(string) b) 
{ 
  return _glob(a,b); 
} 
 
protected function werror = _static_modules._Stdio._stderr->write; 
 
protected void exit(int rc, void | string fmt, void | mixed ... args) 
{ 
  if (fmt) 
    /* Compat werror */ 
    werror(fmt, @args); 
  8.1::exit(rc); 
} 
 
protected Mapping.ShadowedMapping compat_all_constants = 
  Mapping.ShadowedMapping(predef::all_constants(), 
                          ([ 
#if constant(_Debug.HAVE_DEBUG) 
                          "_assembler_debug": _Debug.assembler_debug, 
                            "_debug": _Debug.debug, 
                            "_describe": _Debug.describe, 
                            "_dump_backlog": _Debug.dump_backlog, 
                            "_dump_program_tables": _Debug.dump_program_tables, 
                            "_gc_set_watch": _Debug.gc_set_watch, 
                            "_leak": _Debug.leak, 
                            "_locate_references": _Debug.locate_references, 
                            "_optimizer_debug": _Debug.optimizer_debug, 
#endif /* _Debug.HAVE_DEBUG */ 
                          "_map_all_objects": _Debug.map_all_objects, 
                            "_refs": _Debug.refs, 
                            "_next": _Debug.next, 
                            "_prev": _Debug.prev, 
                            "get_iterator": get_iterator, 
                            "hash": hash_8_0, 
                            "next_object": _Debug.next_object, 
                            "all_constants": all_constants, 
                            "master": master, 
                            "glob" : glob, 
#ifdef constant(System.RegGetValue) 
                            "RegGetValue" : System.RegGetValue, 
                            "RegGetKeyNames" : System.RegGetKeyNames, 
                            "RegGetValues" : System.RegGetValues, 
#endif 
#ifdef constant(System.openlog) 
                            "openlog" : System.openlog, 
                            "syslog" : System.syslog, 
                            "closelog" : System.closelog, 
#endif 
                          "array_sscanf": array_sscanf_80, 
                            "werror" : werror, 
                            "exit" : exit, 
                          ]), 1); 
 
mapping(string:mixed) all_constants() 
{ 
  // Intentional lie in the return type. 
  mixed x = compat_all_constants; 
  return x; 
}