1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
220
  
221
  
222
  
223
  
224
  
225
  
226
  
227
  
228
  
229
  
230
  
231
  
232
  
233
  
234
  
235
  
236
  
237
  
238
  
239
  
240
  
241
  
// 
// Originally by nolar 
// Translated to Pike and expanded by Mirar 
// 
 
#pike __REAL_VERSION__ 
 
//! Decodes the given @[peerid], returning an identification string 
//! for the client software. Assumes the @[peerid] string is exactly 
//! 20 characters long. 
string identify_peer(string peerid) 
{ 
  string id = azureus_style(peerid); 
  if( id ) return id; 
 
  id = shadow_style(peerid); 
  if( id ) return id; 
 
  string old_azureus = peerid[5..5+7-1]; 
  if (old_azureus=="Azureus") return "Azureus 2.0.3.2"; 
 
   string bitcomet = peerid[..0+4-1]; 
   if (bitcomet=="exbc") 
   { 
      string name = "BitComet " 
         +peerid[4]+"." 
         +peerid[5]/10 
         +peerid[5]%10; 
      return name; 
   } 
 
   if( has_prefix(peerid, "XBT") ) 
     return "XBT " + peerid[3..5]/1*"." + (peerid[6]=='d' ? " (debug)":""); 
 
   if( has_prefix(peerid, "OP") ) 
     return "Opera " + peerid[2..5]; 
 
   if( sscanf(peerid, "-ML%s-", id) ) 
     return "MLdonkey "+id; 
 
   if( has_prefix(peerid, "-BOW") ) 
     return "Bits on Wheels"; // Next three are version, A0C == 1.0.6 
 
   id = bram_style(peerid); 
   if( id ) return id; 
 
   if( has_prefix(peerid, "AZ2500BT") ) 
     return "BitTyrant 1.1"; 
 
   if( peerid[0]==0 && peerid[2..3]=="BS" ) 
     return "BitSpirit " + peerid[1]; 
 
   if( peerid[2..3]=="RS" ) 
     return "Rufus " + peerid[..1]; 
 
   if( has_prefix(peerid, "-G3") ) 
     return "G3 Torrent"; 
 
   if( has_prefix(peerid, "FG") ) 
     return "FlashGet"; 
 
   if( has_prefix(peerid, "AP") && peerid[-1]=='-' ) 
     return "AllPeers"; 
 
   if ( has_prefix(peerid, "turbobt") ) 
      return "TurboBT " + peerid[7..7+5-1]; 
 
   string libtorrent = peerid[1..2]; 
   if (libtorrent=="LT") 
   { 
      string version = peerid[3..3+4-1]; 
      string name = "LibTorrent " 
         +version[..3]/1*"."; 
      return name; 
   } 
 
   string btfans = peerid[4..4+6-1]; 
   if (btfans=="btfans") return "SimpleBT"; 
 
   string xantorrent = peerid[..0+10-1]; 
   if (xantorrent=="DansClient") return "XanTorrent"; 
 
   if (peerid[..1]=="Pi") 
   { 
      int c; 
      sscanf(peerid[4..5],"%2c",c); 
      object d=Calendar.Day(c+2452991); 
      return sprintf("Pike Protocols.Torrent %d.%d %4d/%02d/%02d", 
                     peerid[2],peerid[3], 
                     d->year_no(), 
                     d->month_no(), 
                     d->month_day()); 
   } 
 
   int allZero = peerid[..11]=="\0"*12; 
 
   if (allZero) 
   { 
      if ((peerid[12] == 97) && (peerid[13] == 97)) 
         return "Experimental 3.2.1b2"; 
 
      if ((peerid[12] == 0) && (peerid[13] == 0)) 
         return "Experimental 3.1"; 
 
      return "Generic"; 
   } 
 
   if( has_prefix(peerid, "BLZ") ) 
   { 
     int version; 
     sscanf(peerid, "BLZ%3d", version); 
     return "Blizzard " + version; 
   } 
 
#ifdef TORRENT_DEBUG 
   werror("unknown client: %O\n",peerid); 
#endif 
   return "unknown"; 
} 
 
protected string azureus_style(string peerid) 
{ 
  if( peerid[0]!='-' || peerid[7]!='-' ) return 0; 
  string id = peerid[1..2]; 
  int ver; 
  if( sscanf(peerid[3..6], "%d%*1s", ver)!= 1 ) return 0; 
 
  if( id=="AZ" ) 
    return "Azureus " + peerid[3..6]/1*"."; 
 
  id = ([ 
    "AG" : "Ares", 
    "A~" : "Ares", 
    "AR" : "Arctic", 
    "AT" : "Artemis", 
    "AX" : "BitPump", 
    "AZ" : "Azureus", 
    "BB" : "BitBuddy", 
    "BC" : "BitComet", 
    "BF" : "Bitflu", 
    "BG" : "BTG", 
    "BR" : "BitRocket", 
    "BS" : "BTSlave", 
    "BX" : "~Bittorrent X", 
    "CD" : "Enhanced CTorrent", 
    "CT" : "CTorrent", 
    "DE" : "DelugeTorrent", 
    "DP" : "Propagate Data Client", 
    "EB" : "EBit", 
    "ES" : "electric sheep", 
    "FC" : "FileCroc", 
    "FT" : "FoxTorrent", 
    "GS" : "GSTorrent", 
    "HL" : "Halite", 
    "HN" : "Hydranode", 
    "KG" : "KGet", 
    "KT" : "KTorrent", 
    "LH" : "LH-ABC", 
    "LP" : "Lphant", 
    "LT" : "libtorrent", 
    "lt" : "libTorrent", 
    "LW" : "LimeWire", 
    "MO" : "MonoTorrent", 
    "MP" : "MooPolice", 
    "MR" : "Miro", 
    "MT" : "MoonlightTorrent", 
    "NE" : "BT Next Evolution", 
    "NX" : "Net Transport", 
    "OT" : "OmegaTorrent", 
    "PD" : "Pando", 
    "qB" : "qBittorrent", 
    "QD" : "QQDownload", 
    "QT" : "Qt 4 Torrent example", 
    "RT" : "Retriever", 
    "S~" : "Shareaza alpha/beta", 
    "SB" : "~Swiftbit", 
    "SS" : "SwarmScope", 
    "ST" : "SymTorrent", 
    "st" : "sharktorrent", 
    "SZ" : "Shareaza", 
    "TN" : "TorrentDotNET", 
    "TR" : "Transmission", 
    "TS" : "Torrentstorm", 
    "TT" : "TuoTu", 
    "UL" : "uLeecher!", 
    "UT" : "ĀµTorrent", 
    "VG" : "Vagaa", 
    "WT" : "BitLet", 
    "WY" : "FireTorrent", 
    "XL" : "Xunlei", 
    "XT" : "XanTorrent", 
    "XX" : "Xtorrent", 
    "ZT" : "ZipTorrent", 
  ])[id]; 
  if( !id ) return 0; 
 
  return id + " " + ver; 
} 
 
protected string shadow_style(string peerid) 
{ 
  if( peerid[4..6]!="---" ) return 0; 
  string id = ([ 
    'A' : "ABC", 
    'O' : "Osprey Permaseed", 
    'Q' : "BTQueue", 
    'R' : "Tribler", 
    'S' : "Shadow", 
    'T' : "BitTornado", 
    'U' : "UPnP NAT Bit Torrent", 
  ])[peerid[0]]; 
  if( !id ) return 0; 
 
  return id + " " + (array(string))shadow_int( ((array)peerid[1..3])[*] )*"."; 
} 
 
protected int shadow_int(int c) 
{ 
  if( c>='0' && c<='9' ) return c-'0'; 
  if( c>='A' && c<='Z' ) return c-'A'+10; 
  if( c>='a' && c<='z' ) return c-'a'+36; 
  if( c=='.' ) return 62; 
  if( c=='-' ) return 63; 
  return -1; 
} 
 
protected string bram_style(string peerid) 
{ 
  int a,b,c; 
  if( sscanf(peerid, "%*1s%d-%d-%d-", a,b,c)!=4 ) return 0; 
 
  string id = ([ 
    'M' : "Mainline", 
    'Q' : "Queen Bee", 
  ])[peerid[0]]; 
  if( !id ) return 0; 
 
  return sprintf("%s %d.%d.%d", id, a,b,c); 
}