1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
#pike __REAL_VERSION__ 
 
// example HTTP proxy implementation 
 
inherit Protocols.HTTP.Server.Port; 
 
Filesystem.Base fs; 
 
string serverid=version()+": HTTP Proxy"; 
 
string ourvia="Via: "+serverid+" ["+random(1<<128)->digits(16)+"]"; 
 
 
void create(void|int portno, 
            void|string interface) 
{ 
   ::create(Proxify,portno,interface); 
} 
 
class Proxify 
{ 
   class Query 
   { 
      inherit Protocols.HTTP.Query; 
 
      int stillheader=1; 
 
      void write_more() 
      { 
         int i=rid->my_fd->write(buf); 
//     werror("%s: wrote %d\n",rid->full_query,i); 
         buf=buf[i..]; 
         if (!strlen(buf)) 
            rid->my_fd->set_nonblocking(0,0,client_close); 
      } 
 
      void addmyvia() 
      { 
         int i=search(buf,"\r\n\r\n"); 
         if (i!=-1) 
         { 
            buf=buf[..i+1]+ourvia+"\r\n"+buf[i+2..]; 
            stillheader=0; 
         } 
      } 
 
      void send_to_client(string s) 
      { 
         if (!strlen(buf)) 
         { 
            rid->my_fd->set_nonblocking(0,write_more,client_close); 
            buf=s; 
 
            stillheader && addmyvia(); 
 
            write_more(); 
         } 
         else buf+=s; 
         stillheader && addmyvia(); 
      } 
 
      void client_close() 
      { 
//     werror("%s: client close\n",rid->full_query); 
         destruct(con); 
         destruct(this); 
      } 
 
      void async_close() 
      { 
//     werror("%s: server close\n",rid->full_query); 
         rid->finish(0); 
      } 
 
      void async_read(mixed dummy,string data) 
      { 
//     werror("%s: read %d\n",rid->full_query,strlen(data)); 
         send_to_client(data); 
      } 
   } 
 
   Query q=Query(); 
   Protocols.HTTP.Server.Request rid; 
 
   void create(Protocols.HTTP.Server.Request _rid) 
   { 
      rid=_rid; 
//       werror("%O\n",mkmapping(indices(rid),values(rid))); 
 
      Standards.URI url; 
// normal Proxy URL 
      if (rid->not_query[..6]=="http://") 
         url=Standards.URI(rid->not_query); 
// if we're transparent, we at least get a host header (hopefully) 
      else if (rid->request_headers->host) 
      { 
         url=Standards.URI("http://"+ 
                           rid->request_headers->host+"/"+rid->not_query); 
      } 
      else 
      { 
         rid->response_and_finish( (["error":"500", 
                                     "type":"text/html", 
                                     "data":"500 Internal error (Proxy) " 
                                     "can't understand URL (not http?)"]) ); 
         return; 
      } 
 
      string path=url->path; 
      if(path=="") path="/"; 
 
      array v=rid->raw/"\r\n\r\n"+({"",""}); 
      v[0]=(v[0]/"\r\n")[1..]*"\r\n"; // not first line 
 
      if (search(v[0],ourvia)!=-1) 
      { 
         rid->response_and_finish( (["error":"500", 
                                     "type":"text/html", 
                                     "data":"500 Internal error (Proxy) " 
                                     "proxy is recursing"]) ); 
         return; 
      } 
      if (v[0]!="") v[0]+="\r\n"; 
      v[0]+=ourvia+"\r\n"; 
      if (search(v[0],"Host:")==-1) 
         v[0]+="Host: "+url->host+":"+url->port+"\r\n"; 
 
//       werror("%O\n",v); 
 
      q->async_request(url->host,url->port, 
                       rid->request_type+" "+path+ 
                       ((rid->query!="")?("?"+rid->query):"")+" "+ 
                       "HTTP/1.0", 
                       v[0],v[1]); 
   } 
}