1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
/* 
 * $Id: Line.pmod,v 1.1 1998/05/27 20:56:39 grubba Exp $ 
 * 
 * Line-buffered protocol handling. 
 * 
 * Henrik Grubbström 1998-05-27 
 */ 
 
class simple 
{ 
  static object con; 
 
  function handle_data; 
  void handle_command(string data); 
 
  static string multi_line_buffer = ""; 
  static void _handle_command(string line) 
  { 
    if (handle_data) { 
      if (line != ".") { 
        multi_line_buffer += line + "\r\n"; 
      } else { 
        function handle = handle_data; 
        string data = multi_line_buffer; 
        handle_data = 0; 
        multi_line_buffer = ""; 
        handle(data); 
      } 
    } else { 
      handle_command(line); 
    } 
  } 
 
  static string read_buffer = ""; 
  static void read_callback(mixed ignored, string data) 
  { 
    read_buffer += data; 
 
    while(1) { 
      int i = search(read_buffer, "\r\n"); 
      if (i == -1) { 
        return; 
      } 
      data = read_buffer[..i-1];                        // Not the "\r\n". 
      read_buffer = read_buffer[i+2..]; 
      _handle_command(data); 
 
      if (read_buffer == "") { 
        return; 
      } 
    } 
  } 
 
  object(ADT.queue) send_q = ADT.queue(); 
 
  static string write_buffer = ""; 
  static void write_callback(mixed ignored) 
  { 
    while (!sizeof(write_buffer)) { 
      if (send_q->is_empty()) { 
        con->set_write_callback(0); 
        return; 
      } else { 
        write_buffer = send_q->get(); 
        if (!write_buffer) { 
          // EOF 
          con->set_write_callback(0); 
          con->close(); 
          catch { destruct(con); }; 
          con = 0; 
          return; 
        } 
      } 
    } 
    int w = con->write(write_buffer); 
    if (w > 0) { 
      write_buffer = write_buffer[w..]; 
      if (!sizeof(write_buffer)) { 
        if (send_q->is_empty()) { 
          con->set_write_callback(0); 
        } else { 
          write_buffer = send_q->get(); 
          if (!write_buffer) { 
            // EOF 
            con->set_write_callback(0); 
            con->close(); 
            catch { destruct(con); }; 
            con = 0; 
          } 
        } 
      } 
    } else { 
      // Failed to write! 
      werror("write_callback(): write() failed!\n"); 
                      
      con->set_write_callback(0); 
      con->close(); 
      con = 0; 
    } 
  } 
 
  void disconnect() 
  { 
    // Delayed disconnect. 
    send_q->put(0); 
    con->set_write_callback(write_callback); 
    con->set_read_callback(0); 
  } 
     
  static void close_callback() 
  { 
    if (handle_data || sizeof(read_buffer) || sizeof(multi_line_buffer)) { 
      werror("close_callback(): Unexpected close!\n"); 
    } 
    con->close(); 
    con = 0; 
  } 
 
  void create(object con_) 
  { 
    con = con_; 
    con->set_nonblocking(read_callback, 0, close_callback); 
  } 
}; 
 
class smtp_style 
{ 
  inherit simple; 
 
  constant errorcodes = ([]); 
 
  void send(int code, array(string)|string|void lines) 
  { 
    lines = lines || errorcodes[code] || "Error"; 
 
    if (stringp(lines)) { 
      lines /= "\n"; 
    } 
 
    string init = sprintf("%03d", code); 
    string res = ""; 
 
    int i; 
    for(i=0; i < sizeof(lines)-1; i++) { 
      res += init + "-" + lines[i] + "\r\n"; 
    } 
    res += init + " " + lines[-1] + "\r\n"; 
    send_q->put(res); 
    con->set_write_callback(write_callback); 
  } 
};