1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
220
  
221
  
222
  
223
  
224
  
225
  
226
  
227
  
228
  
229
  
230
  
231
  
232
  
233
  
234
  
235
  
236
  
237
  
238
  
239
  
240
  
241
  
242
  
243
  
244
  
245
  
246
  
247
  
248
  
249
  
250
  
251
  
252
  
253
  
254
  
255
  
256
  
257
  
258
  
259
  
260
  
261
  
262
  
263
  
264
  
265
  
266
  
267
  
268
  
269
  
270
  
271
  
272
  
273
  
274
  
275
  
276
  
277
  
278
  
279
  
280
  
281
  
282
  
283
  
284
  
285
  
286
  
287
  
288
  
289
  
290
  
291
  
292
  
293
  
294
  
295
  
296
  
297
  
298
  
299
  
300
  
301
  
302
  
303
  
304
  
305
  
306
  
307
  
308
  
309
  
310
  
311
  
312
  
313
  
314
  
315
  
316
  
317
  
318
  
319
  
320
  
321
  
322
  
323
  
324
  
325
  
326
  
#pike __REAL_VERSION__ 
 
//! Convert Pike code to HTML with syntax highlighting 
//! 
//! @code 
//! pike -x pike_to_html /path/to/file.pike > file.html 
//! @endcode 
 
constant description = "Pike code to syntax highlighted HTML converter"; 
 
constant HELP = #" 
Converts either a string of code or a Pike file into syntax highlighted HTML. 
The generated HTML will be written to stdout. 
 
Usage: 
  pike -x pike_to_html \"path to file or string of code\" 
"; 
 
string delimiters = ",;:.>-+=()|[]&%#!<>^~*/`{}\\"; 
string res_words = "if|else|while|for|foreach|do|return|continue|break|" 
                   "switch|case|default|goto|catch|lambda|gauge|inherit|import"; 
string type = "enum|float|int|typedef|void|object|class|mapping|string|" 
              "array|multiset|mixed|function|program|bool|auto"; 
string modifiers = "public|protected|private|static|constant|local|final|" 
                   "optional|variant|inline"; 
string constants  = "UNDEFINED|__LINE__|__FILE__|__DIR__|__func__|" 
                    "__VERSION__|__MAJOR__|__MINOR__|__BUILD__|" 
                    "__REAL_VERSION__|__REAL_MAJOR__|__REAL_MINOR__|" 
                    "__REAL_BUILD__|__DATE__|__TIME__|__AUTO_BIGNUM__|__NT__|" 
                    "__PIKE__|__amigaos__|true|false|this|this_program"; 
string known_macros = "if|ifdef|define|elif|else|endif|pike|require|include|" 
                      "pragma"; 
 
string namespaces = #"ADT 
Apple 
Arg 
Array 
Audio 
Builtin 
Bz2 
Cache 
Calendar 
Charset 
Colors 
CommonLog 
Concurrent 
Crypto 
DVB 
Debug 
DefaultCompilerEnvironment 
Error 
Filesystem 
Float 
Function 
Fuse 
GDK 
GDK2 
GL 
GLU 
GLUE 
GLUT 
GSSAPI 
GTK 
GTK2 
Gdbm 
Geography 
Getopt 
Git 
Gmp 
Gnome2 
Graphics 
Gz 
HPack 
HTTPLoop 
Image 
Int 
Java 
Languages 
Local 
Locale 
MIME 
Mapping 
Math 
Msql 
Multiset 
Mysql 
NetUtils 
Nettle 
Object 
Odbc 
PDF 
Pango 
Parser 
Pike 
Pipe 
Postgres 
Process 
Program 
Protocols 
Regexp 
Remote 
SANE 
SDL 
SSL 
Search 
Serializer 
Shuffler 
Sql 
Standards 
Stdio 
String 
System 
Thread 
Tools 
Unicode 
VCDiff 
Val 
Web 
Yabu 
Yp 
ZXID 
_Ffmpeg 
__builtin"; 
 
protected multiset(string) delims, reserved, types, consts, ns, mods, macros; 
 
final int(0..1) main(int argc, array(string) argv) 
{ 
  if (argc == 1) { 
    werror("Missing argument.%s\n", HELP); 
    return 1; 
  } 
 
  string h = #"<!doctype html> 
<html> 
  <head> 
    <meta charset='utf-8'> 
    <title>%s</title> 
    <style> 
      html, body { font-family: sans-serif; font-size: 100%%; } 
      pre { font-family: menlo, monospace; font-size: .8rem; } 
      .comment { color: #999; } 
      .type { color: #00007B; font-weight: bold; } 
      .string { color: #037F00; } 
      .macro { color: #B04700; font-weight: bold; } 
      .lang, .const, .mod { color: #863069; font-weight: bold; } 
      .const { color: #0000ff; } 
      .delim { color: #00008e; } 
      .ns { font-weight: bold; } 
      .nested { opacity: .7; transition: opacity .2s ease-in; } 
      .nested:hover { opacity: 1; } 
    </style> 
  </head> 
  <body> 
    <pre lang='pike'>%s</pre> 
  </body> 
</html>"; 
 
  //string code = Stdio.exist(argv[1]) ? Stdio.read_file(argv[1]) : argv[1]; 
 
  string code, title; 
 
  if (Stdio.is_file(argv[1])) { 
    code = Stdio.read_file(argv[1]); 
    title = basename(argv[1]); 
  } 
  else { 
    code = argv[1]; 
    title = "Pike code"; 
  } 
 
  write(sprintf(h, title, convert(code))); 
  return 0; 
} 
 
//! Turn @[code] into HTML. 
//! 
//! The following css classes will be used: 
//! 
//! @ul 
//!  @item 
//!   Delimiters:        delim 
//!  @item 
//!   Reserved words:    lang 
//!  @item 
//!   Data types:        type 
//!  @item 
//!   Constants:         const 
//!  @item 
//!   Modifiers:         mods 
//!  @item 
//!   Root namespaces:   ns 
//!  @item 
//!   Strings:           string 
//!  @item 
//!   Comments:          comment 
//!  @item 
//!   Macros:            macro 
//! @endul 
//! 
//! @param code 
string convert(string code) 
{ 
  delims   = (multiset)(delimiters/1); 
  reserved = (multiset)(res_words/"|"); 
  types    = (multiset)(type/"|"); 
  consts   = (multiset)(constants/"|"); 
  ns       = (multiset)(namespaces/"\n"); 
  mods     = (multiset)(modifiers/"|"); 
  macros   = (multiset)(known_macros/"|"); 
 
  return make_html(Parser.Pike.split(code)); 
} 
 
#define ADDTAG(TYP) add("<span class='" + TYP + "'>" +  \ 
                        replace(tok, ([ "&" : "&amp;",  \ 
                                        "<" : "&lt;",   \ 
                                        ">" : "&gt;" ])) + "</span>") 
#define ADD() add(replace(tok, ([ "&" : "&amp;", "<" : "&lt;", ">" : "&gt;" ]))) 
 
protected string first_non_white(array(string) s) 
{ 
  for (int i; i < sizeof(s); i++) { 
    if (!(< " ", "\t", "\n" >)[s[i]]) 
      return s[i]; 
  } 
} 
 
protected string make_html(array(string) tokens) 
{ 
  String.Buffer buf = String.Buffer(); 
  function add = buf->add; 
 
  tokens = ({ 0 }) + tokens + ({ "  ", "  " }); 
 
  int i; 
  int len = sizeof(tokens) - 2; 
 
  for (i = 1; i < len; i++) { 
    string tok = tokens[i]; 
 
    if (delims[tok]) { 
      ADDTAG("delim"); 
    } 
    else if (mods[tok]) { 
      ADDTAG("mod"); 
    } 
    else if (reserved[tok]) { 
      ADDTAG("lang"); 
    } 
    else if (types[tok]) { 
      ADDTAG("type"); 
    } 
    else if (consts[tok]) { 
      ADDTAG("const"); 
    } 
    else if (ns[tok]) { 
      ADDTAG("ns"); 
    } 
    else { 
      if (sizeof(tok) > 1) { 
        switch (tok[0]) 
        { 
          case '\'': 
            /* fallthrough */ 
          case '"': 
            ADDTAG("string"); 
            break; 
 
          case '/': 
            ADDTAG("comment"); 
            break; 
 
          case '#': 
            if (tok[1] == '"') { 
              ADDTAG("string"); 
            } 
            else { 
              array(string) ntoks = Parser.Pike.split(tok[1..]); 
 
              if (!macros[first_non_white(ntoks)]) { 
                add("#", make_html(ntoks)); 
                break; 
              } 
 
              tok = "#" + ntoks[0]; 
              ADDTAG("macro"); 
 
              if (ntoks[-1] == "\n") 
                ntoks = ntoks[..<1]; 
 
              if (sizeof(ntoks) > 2 && (< "<", "\"" >)[ntoks[2]]) { 
                tok = ntoks[2..]*""; 
                add(ntoks[1]); 
                ADDTAG("string"); 
              } 
              else if (ntoks[0] == "!") { 
                tok = ntoks[1..]*""; 
                ADDTAG("macro"); 
              } 
              else if (sizeof(ntoks) > 1) { 
                tok = ""; 
                if (ntoks[-1][-1] == '\n' && tokens[i+1] == "\n") { 
                  ntoks[-1] = ntoks[-1][..<1]; 
                } 
                add(make_html(ntoks[1..])); 
              } 
            } 
 
            break; 
 
          default: 
            ADD(); 
            break; 
        } 
      } 
      else { 
        ADD(); 
      } 
    } 
  } 
 
  return buf->get(); 
}