1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
#pike __REAL_VERSION__ 
 
//! Instantiates the default Facebook API. 
//! See @[Web.Api.Api()] for further information. 
//! 
//! @param client_id 
//!  Your application key/id 
//! @param client_secret 
//!  Your application secret 
//! @param redirect_uri 
//!  The redirect URI after an authentication 
//! @param scope 
//!  The application scopes to grant access to 
protected this_program `()(string client_id, string client_secret, 
                           void|string redirect_uri, 
                           void|string|array(string)|multiset(string) scope) 
{ 
  return Graph(client_id, client_secret, redirect_uri, scope); 
} 
 
class Graph 
{ 
  inherit Web.Api.Api : parent; 
 
  protected constant AuthClass = Web.Auth.Facebook; 
 
  //! The base uri to the Graph API 
  constant API_URI = "https://graph.facebook.com"; 
 
  //! Getter for the @[Any] object which is a generic object for making request 
  //! to the Facebook Graph API 
  //! 
  //! @seealso 
  //!  @[Any] 
  Any `any() 
  { 
    return _any || (_any = Any()); 
  } 
 
  //! Make a generic @expr{GET@} request to the Facebook Graph API. 
  //! 
  //! @param path 
  //!  What to request. Like @expr{me@}, @expr{me/pictures@}, 
  //!  @expr{[some_id]/something@}. 
  //! 
  //! @param params 
  //! 
  //! @param cb 
  //!  Callback for async requests 
  mapping get(string path, void|ParamsArg params, void|Callback cb) 
  { 
    return `any()->get(path, params, cb); 
  } 
 
  //! Make a generic @expr{PUT@} request to the Facebook Graph API. 
  //! 
  //! @param path 
  //!  What to request. Like @expr{me@}, @expr{me/pictures@}, 
  //!  @expr{[some_id]/something@}. 
  //! 
  //! @param params 
  //! 
  //! @param cb 
  //!  Callback for async requests 
  mapping put(string path, void|ParamsArg params, void|Callback cb) 
  { 
    return `any()->put(path, params, cb); 
  } 
 
  //! Make a generic @expr{POST@} request to the Facebook Graph API. 
  //! 
  //! @param path 
  //!  What to request. Like @expr{me@}, @expr{me/pictures@}, 
  //!  @expr{[some_id]/something@}. 
  //! 
  //! @param params 
  //! 
  //! @param data 
  //! 
  //! @param cb 
  //!  Callback for async requests 
  mapping post(string path, void|ParamsArg params, void|string data, 
               void|Callback cb) 
  { 
    return `any()->post(path, params, data, cb); 
  } 
 
  //! Make a generic @expr{DELETE@} request to the Facebook Graph API. 
  //! 
  //! @param path 
  //!  What to request. Like @expr{me@}, @expr{me/pictures@}, 
  //!  @expr{[some_id]/something@}. 
  //! 
  //! @param params 
  //! 
  //! @param cb 
  //!  Callback for async requests 
  mapping delete(string path, void|ParamsArg params, void|Callback cb) 
  { 
    return `any()->delete(path, params, cb); 
  } 
 
  // Just a convenience class 
  protected class Method 
  { 
    inherit Web.Api.Api.Method; 
 
    //! Internal convenience method 
    public mixed get(string s, void|ParamsArg p, void|Callback cb) 
    { 
      return parent::get(get_uri(METHOD_PATH + s), p, cb); 
    } 
 
    //! Internal convenience method 
    public mixed put(string s, void|ParamsArg p, void|Callback cb) 
    { 
      return parent::put(get_uri(METHOD_PATH + s), p, cb); 
    } 
 
    //! Internal convenience method 
    public mixed post(string s, void|ParamsArg p, void|string data, 
                      void|Callback cb) 
    { 
      return parent::post(get_uri(METHOD_PATH + s), p, data, cb); 
    } 
 
    //! Internal convenience method 
    public mixed delete(string s, void|ParamsArg p, void|Callback cb) 
    { 
      return parent::delete(get_uri(METHOD_PATH + s), p, cb); 
    } 
  } 
 
  //! A generic wrapper around @[Method] 
  protected class Any 
  { 
    inherit Method; 
    protected constant METHOD_PATH = "/"; 
  } 
 
  private Any _any; 
}