1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
/* 
 * $Id: mklibpike.pike,v 1.2 2005/01/03 17:59:05 grubba Exp $ 
 * 
 * Create strapping code for a list of symbols in pike.so, 
 * and the pike headerfiles. 
 * 
 * Henrik Grubbström 2005-01-03 
 */ 
 
constant default_headers = ({ 
  "global.h", 
  "pike_embed.h", 
}); 
 
class C_Include_Handler(array(string) search_path) 
{ 
  string handle_include(string f, string current_file, int local_include) 
  { 
    if (!local_include) { 
      // Ignore system header files. 
      return ""; 
    } else { 
      foreach(search_path, string path) { 
        path = combine_path(path, f); 
        if (file_stat(path)) { 
          return path; 
        } 
      } 
    } 
    return 0;       // Header not found. 
  } 
 
  string read_include(string f) 
  { 
    if (!sizeof(f)) return "";      // System header. 
    return Stdio.read_file(f); 
  } 
} 
 
//! Returns a mapping from symbol to a tuple of return type and parameters. 
mapping(string:array(array(Parser.C.Token))) parse(array(Parser.C.Token) tokens) 
{ 
  mapping(string:array(array(Parser.C.Token))) res = ([]); 
  int i; 
  int start; 
  for (start=i=0; i < sizeof(tokens); i++) { 
    array(Parser.C.Token)|object(Parser.C.Token) token = tokens[i]; 
    if ((objectp(token)) && (token->text == ";")) { 
      if (i > start + 2) { 
        if (objectp(tokens[start]) && (tokens[start]->text == "typedef")) { 
          // Ignore. 
        } else { 
          array(Parser.C.Token)|Parser.C.Token last; 
          if (arrayp(last = tokens[i-1]) && sizeof(last)) { 
            if (last[0]->text == "(") { 
              // Function declaration. 
              res[(string)tokens[i-2]] = ({ 
                tokens[start..i-3], 
                last, 
              }); 
            } else { 
              // { : possible inline function, but probably an struct or enum. 
              // [ : array declaration. 
              // Ignored for now. 
            } 
          } 
        } 
      } else { 
        // Too few tokens to be a function. 
      } 
      start = i+1; 
    } 
  } 
  return res; 
} 
 
int main(int argc, array(string) argv) 
{ 
  array(string) headers = default_headers; 
  array(string) srcdirs = ({ ".", "/home/grubba/src/Pike/7.7/src", }); 
  array(string) symbols = ({ 
    "init_pike", 
    "init_pike_runtime", 
    "pike_set_default_master", 
    "set_pike_debug_options", 
  }); 
 
  Stdio.File out = Stdio.stdout; 
 
  // FIXME: Argument parsing here. 
 
  // Suggested arguments: 
  // 
  //   -h     Help. 
  //   -i     Add include file. 
  //   -I     Add include directory. 
  //   -o     Specify output filename. 
  //   -s     Add single symbol. 
  //   -S     Specify symbol file. 
 
  string raw = cpp(sprintf("%{#include \"%s\"\n%}", headers), "include_all.c", 
                   0, 
                   C_Include_Handler(srcdirs)); 
 
  array(Parser.C.Token|array) tokens = 
    Parser.C.strip_line_statements( 
      Parser.C.hide_whitespaces( 
        Parser.C.group(Parser.C.tokenize(Parser.C.split(raw))) 
      ) 
    ); 
 
  mapping(string:array(array(Parser.C.Token))) symbol_info = parse(tokens); 
 
  int fail; 
  foreach(symbols, string sym) { 
    array(array(Parser.C.Token)) info = symbol_info[sym]; 
    if (!info) { 
      werror("Symbol %O not found!\n", sym); 
      fail = 1; 
      continue; 
    } 
    string rettype = String.trim_whites(Parser.C.simple_reconstitute(info[0])); 
    string params = Parser.C.simple_reconstitute(info[1]); 
    out->write("static %s (*vec_%s)%s;\n" 
               "%s %s%s\n" 
               "{\n" 
               "  %svec_%s(", 
               rettype, sym, params, 
               rettype, sym, params, 
               (rettype=="void")?"":"return ", sym); 
     
    array(array(Parser.C.Token)) args = info[1][1..sizeof(info[1])-2]/({","}); 
    foreach(args; int n; array(Parser.C.Token) arg) { 
      array(Parser.C.Token)|Parser.C.Token name = arg[-1]; 
      if (arrayp(name)) { 
        if (name[0]->text == "(") { 
          // Function pointer arg. 
          name = arg[-2]; 
          if (arrayp(name)) { 
            // Expect something like ( * foo ). 
            // FIXME: Support addresses to function pointers? 
            name = name[2]; 
          } else { 
            // Syntax error. 
            werror("Failed to find variable name in %s\n", 
                   Parser.C.simple_reconstitute(arg)); 
            fail = 1; 
          } 
        } else { 
          // FIXME: Support array notation? 
          werror("Failed to find variable name in %s\n", 
                 Parser.C.simple_reconstitute(arg)); 
          fail = 1; 
        } 
      } 
      out->write("%s%s", n?", ":"", name->text); 
    } 
    out->write(");\n" 
               "}\n\n"); 
  } 
  return fail; 
}