1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
142
  
143
  
144
  
145
  
146
  
147
  
148
  
149
  
150
  
151
  
152
  
153
  
154
  
155
  
156
  
157
  
158
  
159
  
160
  
161
  
162
  
163
  
164
  
165
  
166
  
167
  
168
  
169
  
170
  
171
  
172
  
173
  
174
  
175
  
176
  
177
  
178
  
179
  
180
  
181
  
182
  
183
  
184
  
185
  
186
  
187
  
188
  
189
  
190
  
191
  
192
  
193
  
194
  
195
  
196
  
197
  
198
  
199
  
200
  
201
  
202
  
203
  
204
  
205
  
206
  
207
  
208
  
209
  
210
  
211
  
212
  
213
  
214
  
215
  
216
  
217
  
218
  
219
  
# 
# $Id: configure.in,v 1.5 1998/09/01 17:01:04 hubbe Exp $ 
# 
# Configure script for the mysql-module 
# 
# Henrik Grubbström 
# 
 
# 
# NOTE:  
#   Prior to 3.20.0                         After 3.20.0 
#   -------------------------------------------------------------- 
#   /usr/local/mysql/mach-lib-threads       /usr/local/lib/mysql 
#   /usr/local/mysql/include                /usr/local/include/mysql 
#   libmysql.a                              libmysqllib.a 
#   libstrings.a                    libmystrings.a 
# 
 
 
AC_INIT(mysql.c) 
AC_CONFIG_HEADER(config.h) 
 
sinclude(../module_configure.in) 
 
OLD_LIBS=$LIBS 
OLD_LDFLAGS=$LDFLAGS 
OLD_CPPFLAGS=$CPPFLAGS 
MYSQL_LIBS="" 
 
AC_ARG_WITH(mysql,  [  --without-mysql       no support for the Mysql database],[],[with_mysql=yes]) 
 
if test x$with_mysql = xyes; then 
 
  AC_MSG_CHECKING(Checking for Mysql lib-directory) 
 
  AC_CACHE_VAL(pike_cv_mysql_lib_dir, [ 
    for pike_cv_mysql_lib_dir in /usr/local/lib/mysql /usr/local/mysql/lib/mysql /usr/gnu/lib/mysql /usr/lib/mysql /lib/mysql /usr/local/mysql/lib /usr/local/mysql/mach-lib-thread no; do 
      if test -d $pike_cv_mysql_lib_dir/.; then 
        break 
      else 
        : 
      fi 
    done 
  ]) 
 
  AC_MSG_RESULT($pike_cv_mysql_lib_dir) 
 
  if test x$pike_cv_mysql_lib_dir = xno; then :; else 
    echo Adding $pike_cv_mysql_lib_dir to the library search path. 
    LDFLAGS="-L$pike_cv_mysql_lib_dir ${LDFLAGS}" 
  fi 
 
  AC_MSG_CHECKING(Checking for Mysql include-directory) 
 
  AC_CACHE_VAL(pike_cv_mysql_include_dir, [ 
    for pike_cv_mysql_include_dir in /usr/local/include/mysql /usr/local/mysql/include/mysql /usr/gnu/include/mysql /usr/include/mysql /include/mysql /usr/local/mysql/include no; do 
      if test -d $pike_cv_mysql_include_dir/.; then 
        break 
      else 
        : 
      fi 
    done 
  ]) 
 
  AC_MSG_RESULT($pike_cv_mysql_include_dir) 
 
  if test x$pike_cv_mysql_include_dir = xno; then :; else 
    echo Adding $pike_cv_mysql_include_dir to the include search path. 
    CPPFLAGS="-I$pike_cv_mysql_include_dir ${CPPFLAGS}" 
  fi 
 
  # Header file 
 
  AC_CHECK_HEADERS(winsock.h mysql.h mysql/mysql.h) 
 
  # Mysql libs 
 
  pike_cv_mysql="unknown" 
 
  AC_CHECK_LIB(mystrings, bchange, [ 
    LIBS="-lmystrings $LIBS" 
    MYSQL_LIBS="-lmystrings ${MYSQL_LIBS}" 
    pike_cv_mysql="post3.20" 
  ], [ 
    AC_CHECK_LIB(strings, bchange, [ 
      LIBS="-lstrings $LIBS" 
      MYSQL_LIBS="-lstrings ${MYSQL_LIBS}" 
      pike_cv_mysql="pre3.20" 
    ], []) 
  ]) 
 
  AC_MSG_CHECKING(Mysql version) 
 
  AC_MSG_RESULT($pike_cv_mysql) 
 
  # System libs which might be needed 
 
  if echo $LIBS|grep -- -lsocket >&5 2>&5; then 
    : 
  else 
    AC_CHECK_LIB(socket, socket, [ 
      LIBS="-lsocket $LIBS" 
      MYSQL_LIBS="-lsocket ${MYSQL_LIBS}" 
    ], []) 
  fi 
  if echo $LIBS|grep -- -lnsl >&5 2>&5; then 
    : 
  else 
    AC_CHECK_LIB(nsl, gethostbyname, [ 
      LIBS="-lnsl $LIBS" 
      MYSQL_LIBS="-lnsl ${MYSQL_LIBS}" 
    ], []) 
  fi 
  if echo $LIBS|grep -- -lm >&5 2>&5; then 
    : 
  else 
    AC_CHECK_LIB(m, floor, [ 
      LIBS="-lm $LIBS" 
      MYSQL_LIBS="-lm ${MYSQL_LIBS}" 
    ], []) 
  fi 
 
  # Pthreads is still needed in 3.20.0. 
  AC_CHECK_FUNC(pthread_self, [], [ 
    AC_CHECK_LIB(pthread, pthread_self, [ 
      LIBS="-lpthread $LIBS" 
      echo Warning added -lpthread to \$LIBS\! 
    ], [ 
      AC_CHECK_LIB(pthreads, pthread_self, [ 
        LIBS="-lpthreads $LIBS" 
        echo Warning added -lpthreads to \$LIBS\! 
      ], []) 
    ]) 
  ]) 
 
  AC_CHECK_LIB(dbug, _db_doprnt_, [ 
    LIBS="-ldbug $LIBS" 
    MYSQL_LIBS="-ldbug ${MYSQL_LIBS}" 
  ], []) 
 
  AC_CHECK_LIB(mysys, my_init, [ 
    LIBS="-lmysys $LIBS" 
    MYSQL_LIBS="-lmysys ${MYSQL_LIBS}" 
  ], []) 
 
  # Try a couple of mysqlclient libs 
  # in order of age, newest first. 
 
define([AC_CHECK_SQLLIB], 
[ 
AC_MSG_CHECKING(for mysql_connect in $1) 
AC_CACHE_VAL(ac_cv_pike_lib_$1_mysql_connect, 
[ 
  ac_save_LIBS="$LIBS" 
LIBS="-l$1 $LIBS" 
  AC_TRY_LINK( 
[ 
#ifdef HAVE_WINSOCK_H 
#include <winsock.h> 
#endif 
 
#ifdef HAVE_MYSQL_H 
#include <mysql.h> 
#else 
#ifdef HAVE_MYSQL_MYSQL_H 
#include <mysql/mysql.h> 
#endif 
#endif 
],[ 
  mysql_connect(0,0,0,0); 
],ac_cv_pike_lib_$1_mysql_connect=yes,ac_cv_pike_lib_$1_mysql_connect=no) 
LIBS="$ac_save_LIBS" 
]) 
 
if test "x$ac_cv_pike_lib_$1_mysql_connect" = xyes ; then 
  AC_MSG_RESULT(yes) 
  $2 
else 
  AC_MSG_RESULT(no) 
  $3 
fi 
]) 
 
  AC_CHECK_SQLLIB(mysqlclient, [ 
    LIBS="-lmysqlclient $LIBS" 
    MYSQL_LIBS="-lmysqlclient ${MYSQL_LIBS}" 
  ], [  
    AC_CHECK_SQLLIB(mysqllib, [ 
      LIBS="-lmysqllib $LIBS" 
      MYSQL_LIBS="-lmysqllib ${MYSQL_LIBS}" 
    ], [ 
      AC_CHECK_SQLLIB(mysql, [ 
        LIBS="-lmysql $LIBS" 
        MYSQL_LIBS="-lmysql ${MYSQL_LIBS}" 
      ], [ pike_cv_mysql="no" ]) 
    ]) 
  ]) 
 
  if test x$pike_cv_mysql = xno; then 
    # Restore variables, so we don't link with unnessesary libs 
 
    LIBS=$OLD_LIBS 
    CPPFLAGS=$OLD_CPPFLAGS 
    LDFLAGS=$OLD_LDFLAGS 
    MYSQL_LIBS="" 
  else 
    AC_DEFINE(HAVE_MYSQL) 
 
    # Note: mysql_port and mysql_unix_port aren't functions, but that shouldn't matter 
    AC_CHECK_FUNCS(mysql_real_query mysql_fetch_lengths mysql_port mysql_unix_port) 
  fi 
else 
  : 
fi 
 
AC_SUBST(MYSQL_LIBS) 
 
AC_OUTPUT(Makefile,echo FOO >stamp-h )