1
  
2
  
3
  
4
  
5
  
6
  
7
  
8
  
9
  
10
  
11
  
12
  
13
  
14
  
15
  
16
  
17
  
18
  
19
  
20
  
21
  
22
  
23
  
24
  
25
  
26
  
27
  
28
  
29
  
30
  
31
  
32
  
33
  
34
  
35
  
36
  
37
  
38
  
39
  
40
  
41
  
42
  
43
  
44
  
45
  
46
  
47
  
48
  
49
  
50
  
51
  
52
  
53
  
54
  
55
  
56
  
57
  
58
  
59
  
60
  
61
  
62
  
63
  
64
  
65
  
66
  
67
  
68
  
69
  
70
  
71
  
72
  
73
  
74
  
75
  
76
  
77
  
78
  
79
  
80
  
81
  
82
  
83
  
84
  
85
  
86
  
87
  
88
  
89
  
90
  
91
  
92
  
93
  
94
  
95
  
96
  
97
  
98
  
99
  
100
  
101
  
102
  
103
  
104
  
105
  
106
  
107
  
108
  
109
  
110
  
111
  
112
  
113
  
114
  
115
  
116
  
117
  
118
  
119
  
120
  
121
  
122
  
123
  
124
  
125
  
126
  
127
  
128
  
129
  
130
  
131
  
132
  
133
  
134
  
135
  
136
  
137
  
138
  
139
  
140
  
141
  
/* vim:syntax=ragel 
 */ 
#define HEX2DEC(x) ((x) <= '9' ? (x) - '0' : ((x) < 'G') ? (x) - 'A' + 10 : (x) - 'a' + 10) 
 
%%{ 
    machine JSON_string; 
    alphtype int; 
    include JSOND "json_defaults.rl"; 
    getkey ((int)INDEX_PCHARP(str, fpc)); 
 
    action hex0beg { 
        hexchr0 = HEX2DEC(fc); 
    } 
 
    action hex0mid { 
        hexchr0 *= 16; 
        hexchr0 += HEX2DEC(fc); 
    } 
 
    action hex0end { 
        if (IS_HIGH_SURROGATE (hexchr0)) { 
            /* Chars outside the BMP can be expressed as two hex 
             * escapes that codes a surrogate pair, so see if we can 
             * read a second one. */ 
            fnext hex1; 
        } 
        else { 
            if (IS_NUNICODE(hexchr0)) { 
                fpc--; fbreak; 
            } 
            if (validate) { 
                string_builder_putchar(&s, hexchr0); 
            } 
        } 
    } 
 
    action hex1beg { 
        hexchr1 = HEX2DEC(fc); 
    } 
 
    action hex1mid { 
        hexchr1 *= 16; 
        hexchr1 += HEX2DEC(fc); 
    } 
 
    action hex1end { 
        if (!IS_LOW_SURROGATE (hexchr1)) { 
            fpc--; fbreak; 
        } 
        if (validate) { 
            int cp = (((hexchr0 - 0xd800) << 10) | (hexchr1 - 0xdc00)) + 
                0x10000; 
            string_builder_putchar(&s, cp); 
        } 
    } 
 
    action add_unquote { 
        if (validate) switch(fc) { 
            case '\'': 
            case '"': 
            case '/': 
            case '\\':      string_builder_putchar(&s, fc); break; 
            case 'b':       string_builder_putchar(&s, '\b'); break; 
            case 'f':       string_builder_putchar(&s, '\f'); break; 
            case 'n':       string_builder_putchar(&s, '\n'); break; 
            case 'r':       string_builder_putchar(&s, '\r'); break; 
            case 't':       string_builder_putchar(&s, '\t'); break; 
        } 
    } 
 
    action mark { 
        mark = fpc; 
    } 
 
    action mark_next { mark = fpc + 1; } 
 
    action string_append { 
        if (fpc - mark > 0) { 
            if (validate) 
                    string_builder_append(&s, ADD_PCHARP(str, mark), fpc - mark); 
        } 
    } 
 
    main := '"' . ( 
                   start: ( 
                       '"' >string_append -> final | 
                       '\\' >string_append -> unquote | 
                       (unicode - [\\"]) -> start 
                   ), 
                   unquote: ( 
                       ['"\\/bfnrt] >add_unquote -> start | 
                       'u' . xdigit >hex0beg . (xdigit{3} $hex0mid) @hex0end -> start 
                   ) @mark_next, 
                   hex1: ( 
                       '\\u' . xdigit >hex1beg . (xdigit{3} $hex1mid) @hex1end -> start 
                   ) @mark_next 
                  ) >mark %*{ fpc--; fbreak; }; 
}%% 
 
static ptrdiff_t _parse_JSON_string(PCHARP str, ptrdiff_t p, ptrdiff_t pe, struct parser_state *state) { 
    int hexchr0, hexchr1; 
    ptrdiff_t start = p, mark = 0; 
    struct string_builder s; 
    int cs; 
    ONERROR handle; 
    const int validate = !(state->flags&JSON_VALIDATE); 
 
    %% write data; 
 
    if (validate) { 
        init_string_builder(&s, 0); 
        SET_ONERROR (handle, free_string_builder, &s); 
    } 
 
    %% write init; 
    %% write exec; 
 
    if (cs < JSON_string_first_final) { 
        if (validate) { 
            UNSET_ONERROR(handle); 
            free_string_builder(&s); 
        } 
 
        state->flags |= JSON_ERROR; 
        if (p == pe) { 
            err_msg = "Unterminated string"; 
            return start; 
        } 
        return p; 
    } 
 
    if (validate) { 
        push_string(finish_string_builder(&s)); 
        UNSET_ONERROR(handle); 
    } 
 
    return p; 
} 
 
#undef HEX2DEC